[DECORATE] Making a projectile stick to an enemy?

[Recurracy]

Hello again, right now I'm trying to recreate the aerosol can from Blood. But I'm having trouble figuring out how to make the fire stick to an enemy, as if he's actually on fire. Can anyone help?

[Lagi]

not sure if you want something more complicated than basic stuff

1. if you using hitscan (no projectile, like a bullet) weapon (like https://zdoom.org/wiki/A_FireBullets) they have buff string inside the function (check it on wiki)

create a puff with flag +PUFFONACTORS (so no blood is display)
adjust in Spawn: how long the puff should be display (by amount of letters ABC.. and tic time "3"

Code: Select all

ACTOR burnpuff 
{
  RenderStyle Translucent
  Alpha 0.4
  VSpeed 0.3
  damagetype fire
  +NOBLOCKMAP
  +NOGRAVITY
  +PUFFONACTORS
  States
  {
  Spawn:
    burn ABCABCABCABCABC 3 Bright
    Stop
  }
}

2. if you use some flame projectile for aerosol can

use somewhere in your weapon
TNT1 A 0 A_FireProjectile ("nameofprojectile" ,,,
https://zdoom.org/wiki/A_FireProjectile

create projectile actor, and in Death state of that projectile specify how long the flame should last (its "FHFX STUVW 4" below)

Code: Select all

ACTOR DryHammerMissile
{
  Radius 10
  Height 20
  Speed 30 
  Damage (random(140,200))
  Projectile
  +WINDTHRUST
  +THRUGHOST
  -NOGRAVITY
	Gravity 0.7
	DeathSound "FighterHammerExplode"
  Obituary "$OB_MPFWEAPHAMMERR"
  States
  {
  Spawn:
    DHFX A 2 Bright
    DHFX B 2 Bright A_PlaySound("FighterHammerContinuous")
    DHFX CDEFGH 2 Bright
    Loop
  [b]Death:
    TNT1 A 0 A_Jump (42, 2)
  	TNT1 A 0 A_SpawnItemEx ("justhammer")
	FHFX STUVW 4
    Stop[/b]
  }
}

[Jarewill]

not sure if you want something more complicated than basic stuff

Sorry to say this, but this won't actually make it stick to the target.

While I am not an expert of Blood, I know which weapon and feature you are talking about.
I'll provide a working example, but keep in mind that you still need to provide the required actors.

---

Code: Select all

ACTOR Projectile
{
  +HITTRACER //This is important to know who it should stick to
  States
  {
  Death:
    TNT1 A 0 A_SpawnItemEx("ProjectileDeathEffect") //If you want a custom death animation, you need to create a new actor that plays it and spawn it with this, otherwise not needed
    TNT1 AAAAAAAA 1 //Repeat this as many times as you need it to last (just add more A's)
    {
	 A_SpawnItemEx("FireEffect",random(-16,16),random(-16,16),random(16,64)); //This spawns FireEffect actors every tick in random locations
	 A_SpawnProjectile("FireDamage",0,0,0,CMF_TRACKOWNER|CMF_CHECKTARGETDEAD,0,AAPTR_TRACER); //If you also want for the effect to hurt the monster, otherwise also not needed
	 A_Warp(AAPTR_TRACER,0,0,0,0,WARPF_NOCHECKPOSITION); //And this warps the projectile right to the target's location
    }
    Stop
  }
}

This should work, just copy the +HITTRACER flag and the Death state onto your flame projectile.

[Lagi]

not sure if you want something more complicated than basic stuff

Sorry to say this, but this won't actually make it stick to the target.

No worries, thank you for hittracer, it can be useful for me

EDIT:

here is what to do to make Puff (not projectile) stick to victim. In case of f.ex. melee attack with fire or explosions (with fire puff effect).
important flags:
+PUFFONACTORS
+PUFFGETSOWNER
+HITTRACER

and

A_Warp(AAPTR_TRACER, 2, 0, -5, 0, WARPF_NOCHECKPOSITION|WARPF_INTERPOLATE,"",0.6)

---

last "0.6" parametr will place fire puff at 0.6 height of the actor, otherwise some dudes are too small while other too tall, for correct fire placement (you can also adjust it with zoff "-5" - to reach perfect position in each case.
Small actor less affected by 0.6, more by -5.
Tall actor more affected by 0.6 less by -5.

Code: Select all

ACTOR burnpuff 
{
  RenderStyle Translucent
  Alpha 0.8
  VSpeed 0.3
  damagetype fire
  +NOBLOCKMAP
  +NOGRAVITY
  +PUFFONACTORS
  +PUFFGETSOWNER
  +HITTRACER
  AttackSound "PLRBURN"
  States
  {
 Spawn: 
    burn ABCABCABCABCABC 3 Bright A_Warp(AAPTR_TRACER, 1, 0, -5, 0, WARPF_NOCHECKPOSITION|WARPF_INTERPOLATE,"",0.6)
    Stop
  }
}

[Aerosplinter]

Is there also a way where the projectile can be able to trigger infighting?

For me, I am trying to make an enemy use projectiles that stick to whoever is struck by that.