"How do I ZScript?"

[Xaser]

Actually, ZScript guards every single pointer dereference, but when you call a function things are a bit different: The pointer is never dereferenced unless you call a virtual function - it's just being passed as a hidden function parameter, which prevents checking in the call instruction because it isn't part of that - the exception only gets triggered when the pointer actually gets used inside the called function.

I suppose it's more accurate then to say that "self" isn't checked for null since it's being treated like any other function parameter?

I do find it convenient that the way the system appears to work the same as C++ in this case, even if there's some abstraction covering the real bits.

[Matt]

Thanks for the explanation! I think I have an idea what the problem might be but I'll have to try out the possible solutions I have in mind before commenting further... glad it's not some silly overflow issue at least.

[Graf Zahl]

I suppose it's more accurate then to say that "self" isn't checked for null since it's being treated like any other function parameter?

It isn't just treated like any other function parameter, for the compiler it IS just another function parameter that gets added to the list internally.

[Matt]

So I tried to reference self in a line immediately before the one that the stack trace is pointing to:

Code: Select all

class HDActor:Actor{
	void nexttic(){
		if(!CheckNoDelay()) return;
		if(tics!=-1){
			if(tics>0)tics--;
			while(!tics){
A_LogInt(self.pos.x);
				if(!SetState(CurState.NextState)){
					return;
				}
			}
		}
	}
}

Same crash to console, but it's still pointing to the SetState call not the A_LogInt.

What could possibly be null then?

[Graf Zahl]

Most likely CurState is null, then.

[ZZYZX]

If your point is to make the specific actor's ticrate faster, just call Tick() manually, like self.Tick().

[Gutawer]

How can I get the current gravity acting on an actor (not just their gravity property, but also taking into account map gravity & sector gravity), and the current air friction acting on an actor (I know the wiki has a formula for getting air friction based off air control, so getting air control would also be fine)?

[ZZYZX]

In global level struct:
native double gravity;
native double aircontrol;
native double airfriction;

Use like level.gravity, level.aircontrol, level.airfriction...
(this can be found in gzdoom.pk3/zscript/base.txt)

In Sector struct:
native double gravity;

You can get the current sector of the actor by using self.CurSector.

Just check these values and compare them to your input, and see what and how gets modified when you alter a sector's gravity for example... Then combine the values and you will get your gravity that affects the actor
Note that you will also need to check for NOGRAVITY and FLOAT (?) flags, as well as being submerged... and I don't know how that works really. Probably something hardcoded.

Actually, in Actor class:
native double GetGravity();
native double, double GetFriction();

That's probably why that method is in, it should return you the actual total gravity and friction. Try that.

[Matt]

My only purpose for the separate nexttic() function was so I didn't need to retype all of that every time I tried to use a custom Tick() override.

I've made a standalone version here:

---

Code: Select all

class stupid:actor{
	bool stopped;
	states{
	spawn:
		BAL1 A -1;
		wait;
	death:
		TNT1 A 0;
		stop;
	}
	override void tick(){
		if(globalfreeze||level.Frozen) return;
		clearinterpolation();
		if(!stopped){
			vel.z--;
			int spd=abs(vel.x);if(abs(vel.y)>spd)spd=abs(vel.y);
			vector2 frac=self.vel.xy*radius/spd;
			for(int i=0;i<spd;i+=radius){
				if(!trymove(self.pos.xy+frac,true)){
					A_PlaySound(bouncesound);
					vel.xy*=-1;
					vel.xy+=(random(-1,1),random(-1,1));
				}
			}
			setz(pos.z+vel.z);
			if(pos.z<getzat())setz(getzat());
			if(pos.z+height>getzat(flags:GZF_CEILING))setz(getzat(flags:GZF_CEILING)-height);
			if(
				pos.z==getzat()
				||pos.z+height==getzat(flags:GZF_CEILING)
			){
				if(abs(vel.z)>2){
					A_PlaySound(bouncesound);
					vel.xy+=(random(-1,1),random(-1,1));
					vel.z*=-bouncefactor;
				}else{
					vel.xy*=bouncefactor;
					vel.z=0;
				}
			}
			if(abs(vel.x)+abs(vel.y)+abs(vel.z)<1){
				stopped=true;
				setstatelabel("death");
			}
		}else{
			if(getzat()<pos.z){
				stopped=false;vel.z--;setstatelabel("spawn");
			}
			if(getzat()>pos.z) setz(getzat());
		}
		if(!CheckNoDelay()) return;
		if(tics!=-1){
			if(tics>0)tics--;
			while(!tics){
				if(!SetState(CurState.NextState)){
					return;
				}
			}
		}
	}
}

This will cause the dereference. If either I comment out 'setstatelabel("death");' or set the TNT1 A 0 to non-zero, the dereference (or at least the crash) does not happen.

I'm guessing then that the sequence is something like:

1. it sees the setstatelabel and applies it right away; but then
2. it processes the death state immediately; so
3. by the time we get to setstate call, the actual state has already reached "stop" and so the current state is null?

If so, would I be safe just making sure none of these setstatelabels are pointing to anything with a zero length?

[Matt]

Is there any way to explicitly call the corpse-rasing process without relying on A_Chase and CHF_RESURRECT?

[Major Cooke]

Thing_Raise(tid)

Quick question, Graf, what is the schematic of Color? I noticed there were four parameters when used directly from the menu system in zscript.

[Graf Zahl]

This will cause the dereference. If either I comment out 'setstatelabel("death");' or set the TNT1 A 0 to non-zero, the dereference (or at least the crash) does not happen.

I'm guessing then that the sequence is something like:

1. it sees the setstatelabel and applies it right away; but then
2. it processes the death state immediately; so
3. by the time we get to setstate call, the actual state has already reached "stop" and so the current state is null?

SetState will destroy the actor if it reaches a state with zero duration and no next state.

[/quote]
If so, would I be safe just making sure none of these setstatelabels are pointing to anything with a zero length?[/quote]

You better check 'bDestroyed' after the SetState call, that's safer.

[Matt]

Thanks Graf! Adding "if(bdestroyed) return;" works like a charm.

As for the ACS suggestion for a ZScript question, I ended up with this:

Code: Select all

		TROO A 0{
			int oldtid=healtarget.tid;
			int newtid=FindUniqueTid();
			healtarget.ChangeTid(newtid);
			Thing_Raise(newtid);
			healtarget.ChangeTid(oldtid);
		}

which still doesn't work because the healer is very frequently always just a little inside the corpse's hitbox and that's registered as a block.

Is there any way around this?

EDIT: for anyone curious, so far this works ("A_HDMRaise" is almost identical to the alternative, it just takes advantage of a few custom variables so we don't blithely assume every raisable is 56 tall with a maxstepheight of 24):

---

Code: Select all

		TROO A 0{
			if(!healtarget) return;
			if(!healtarget.bcorpse) return;
			let ht=HDMOb(healtarget);
			if(ht){
				ht.A_HDMRaise();
			}else{
				healtarget.A_PlaySound("misc/gibbed");
				healtarget.A_TakeInventory("SawGib");
				healtarget.A_SetSize(-1,56);
				healtarget.maxstepheight=24;
				healtarget.bcorpse=null;
				healtarget.bkilled=null;
				healtarget.A_SetHealth(healtarget.spawnhealth());
				healtarget.bsolid=true;
				healtarget.bshootable=true;
				healtarget.balwaystelefrag=false;
				healtarget.bnotautoaimed=false;
				healtarget.setstatelabel("raise");
			}
			healtarget=null;
		}

[Nash]

What is this "new" keyword and how is it actually meant to be used? How is it better than just doing FMyClass blah; ?

[Graf Zahl]

One creates a new object, the other is just a pointer.