Flashlight mechanics

[Hidden Hands]

Can someone either explain to me how I can implement a flashlight for dark areas similar to Doom 3 but that requires batteries or alternatively a link to a ready made one? I'm sure Interstellar Enforcer used a similar mechanic.

Thanks in advance.

[Jarewill]

To make a flashlight, you would have to either spawn a bunch of light actors in DECORATE, or make a spotlight in ZScript.
The ZScript spotlight method is of course better. Both in looks and performance.
There is a very handy flashlight mod here that can be easily edited with a powerup.

As for making it have a depleting battery, you would need to do some CustomInventory wizardry.
Here is a working one:

---

Code: Select all

ACTOR CustomFlashlight : CustomInventory
{
  Inventory.PickupMessage "Picked up a flashlight."
  Inventory.Icon "LITEA0"
  Inventory.Amount 100
  Inventory.MaxAmount 100
  Inventory.InterHubAmount 100 //This keeps up to 100% battery when travelling through hubs, so it won't reset to 1%
  Inventory.PickupSound "misc/i_pkup"
  +INVENTORY.INVBAR
  +INVENTORY.KEEPDEPLETED //This makes the flashlight be kept in inventory when it reaches 0% (can't be used though)
  states
  {
  Spawn:
    LITE A -1
    Stop
  Use:
	TNT1 A 0 A_JumpIfInventory("PowerFlashlight",1,4) //If flashlight powerup in inventory, turn off the light
	TNT1 A 0 A_Overlay(-5,"UseReal") //Overlay for depleting batteries
	TNT1 A 0 A_PlaySound("weapons/sshoto") //Flashlight on sound
	TNT1 A 0 A_GiveInventory("PowerFlashlight",1) //Give flashlight powerup
	Fail
	TNT1 A 0 A_Overlay(-5,"") //Stop depleting
	TNT1 A 0 A_PlaySound("weapons/sshotc") //Flashlight off sound
	TNT1 A 0 A_TakeInventory("PowerFlashlight",1) //Take flashlight powerup
	Fail
  UseReal:
	TNT1 A 0 A_JumpIfInventory("CustomFlashlight",2,1) //If above 1% battery, jump
	Goto UseLast //If at 1%, jump to UseLast
	TNT1 A 0 A_TakeInventory("CustomFlashlight",1) //Take 1% battery
	TNT1 A 42 //Wait 42 tics (sums up to about 2 minutes [120 / 100 * 35] )
	Loop
  UseLast:
	TNT1 A 0 A_PlaySound("weapons/sshotc") //Flashlight off sound
	TNT1 A 0 A_TakeInventory("PowerFlashlight",1) //Take flashlight powerup
	TNT1 A 0 A_TakeInventory("CustomFlashlight",1) //End the flashlight
    Stop
  }
}

[Enjay]

The flashlight I carry with me when I'm walking my dog: battery life 3 years and counting (used every day).

Game flashlight: battery life 1 minute if you're lucky.