[code] Alternate raise states

[Ichor]

Let's say you want a monster to be able to revive other monsters. We all know how to do that. However, suppose you want another monster in your project to do something else to a corpse besides raise it up (for instance, devour the corpse). Well, I have just discovered a way to do this, although it's not quite perfect. I was going to use it myself for corpse explosion, but it was too much trouble, and it won't work if something is standing on the corpse, even a tiny bit. This seriously limits its effectiveness. Still, I think this could be useful. Anyway...

---

Code: Select all

ACTOR Vilefake2
{
    PROJECTILE
    +FRIENDLY
    +NOCLIP
    +DONTSPLASH
    +FORCERADIUSDMG
    +FORCEPAIN
    +RIPPER
    +BLOODLESSIMPACT
    Radius 80
    Height 5
    Speed 40
    RENDERSTYLE NONE
    DamageType "Whatever"
    States
    {
    Spawn:
        TNT1 A 0
        TNT1 AAAAAAAA 6 A_VileChase
        Stop
    Death:
        TNT1 A 1
        Stop
    Heal:
        TNT1 A 2
        TNT1 A 0 A_Explode(1,128,0,0,1)
        Stop 
    }
}

This revives the monster, then almost immediately explodes with a custom damagetype. This is to force the revived monster into a different state instead of just reviving it. In this case here, it's just a projectile, but it should work with normal monsters.

---

Code: Select all

Actor FImp : DoomImp 7004
{
    +FLOORCLIP
    PainChance "Whatever", 255
    States
    {
    Pain.Whatever:
	TNT1 A 0 A_JumpIfInventory("DeadThing",1,"Whatever")
	Goto Pain
    See:
	TNT1 A 0 A_TakeInventory("DeadThing",1)
	TROO AABBCCDD 3 A_Chase
	Loop
    Missile:
	TROO EF 8 A_FaceTarget
	TROO G 6 A_TroopAttack
	Goto See
    Pain:
	TROO H 2
	TROO H 2 A_Pain
	Goto See
    Death:
	TNT1 A 0 A_JumpIfInventory("DeadThing",1,"Whatever")
	TNT1 A 0 A_GiveInventory("DeadThing",1)
	TROO I 8
	TROO J 8 A_Scream
	TROO K 6
	TROO L 6 A_NoBlocking
	TROO M -1
	Stop
    XDeath:
	TNT1 A 0 A_JumpIfInventory("DeadThing",1,"Whatever")
	TNT1 A 0 A_GiveInventory("DeadThing",1)
	TROO N 5 A_XScream
	TNT1 AAAAAA 0 A_TossGib
	TROO O 5 A_TossGib
	TROO O 5 A_Fall
	TROO QRST 5
	TROO U -1
    Raise:
	TROO ML 8
	TROO KJI 6
	TNT1 A 0 A_TakeInventory("DeadThing",1)
	Goto See
    Whatever:
	NULL A 0 A_NewStuffGoesHere
	Stop
    }
}

ACTOR DeadThing : Inventory
{
    Inventory.Amount 1
    Inventory.MaxAmount 1
}

The DeadThing inventory is to make sure the monster will not do the new thing if that damagetype hits the monster and it isn't being revived.

[ShadesMaster]

Hmmm... interesting! The potential is endless!