[Question] Mass Resurrection?

[RV-007]

If you know the Archvile to resurrect corpses, then you might know what I am asking for.

How do I make a monster/item to mass resurrect corpses? I used A_RadiusGive to corpses, but I only managed to apply only items. The resurrection function is under the monster department so I have a problem somewhere.

[Vaecrius]

What comes to mind for me:

A_RadiusGive a custominventory item that, on pickup, spawns an invisible, very very slow moving (or speed 0), nonshootable monster that inherits its spawner's pointers. It goes into A_Chase, has no melee or missile states, and disappears at the end of its Heal state.

No idea if this works or not but I might try it sometime later.

EDIT:

Spoiler:

Code: Select all • Expand view

...
      VILE H 0 A_RadiusGive("Raiser", 256, RGF_CORPSES|RGF_MONSTERS,1)
...

actor Raiser : CustomInventory
{
   states
   {
   pickup:
      TNT1 A 0 A_SpawnItemEx("RaiserDummy",0,0,0,velx,vely,velz,0,SXF_TRANSFERPOINTERS|SXF_NOCHECKPOSITION)
      stop
   }
}
actor RaiserDummy
{
   -solid
   -shootable
   +noblockmap
   states
   {
   spawn:
      TNT1 AAAAAAAAAAAAAAA 1 A_Chase("","",CHF_RESURRECT|CHF_DONTMOVE)
      stop
   heal:
      TNT1 A 1
      stop
   }
}

EDIT2: Thing_Raise(0) also works, but you'll have to do something to keep a mass of raising monsters from looking perfectly synchronized (which looks utterly bizarre for a large group of similarly killed monsters of the same type - even a difference of a few tics can help).

[RV-007]

A lot of indirectness going on, lol.

[FDARI]

Does the special Thing_Raise(int tid) work?

Code: Select all • Expand view

actor RaiseMe : CustomInventory
{
    states
    {
        pickup:
            tnt1 a 0 thing_raise(0)
            stop
    }
}

A_RadiusGive that?

[RV-007]

Unfortunately I do not know what are the capability of corpses nor know when a monster has a +ISCORPSE actor flag.

I tried spawning some monsters in the place of corpses, but to no avail. Is it possible to heal monsters in this way? Not as good as resurrecting monster corpses, but this makes a real healer monster at a distance. Also, this could make mass status effect to the targets.

Here is my attempted code:

Spoiler: Code for Archvile to mass resurrect w/ A_VileTarget in its missile state

/*
Archvile
blah
link

http://zdoom.org/wiki/Classes:Archvile
http://zdoom.org/wiki/A_LookEx
http://zdoom.org/wiki/A_Chase
http://zdoom.org/wiki/A_FaceTarget
*/
ACTOR ArchvileMonster : Archvile 64
{
Game Doom
SpawnID 111
Health 700
Radius 20
Height 56
Mass 500
Speed 15 //1.5
PainChance 10
MaxTargetRange 896
MONSTER
+QUICKTORETALIATE
+FLOORCLIP
+NOTARGET
+ALWAYSFAST
SeeSound "vile/sight"
PainSound "vile/pain"
DeathSound "vile/death"
ActiveSound "vile/active"
MeleeSound "vile/stop"
Obituary "%o was incinerated by an Archvile." //"$OB_VILE" //"%o was incinerated by an archvile."

States
{
Spawn:
VILE ABCDEF 10 A_LookEx (0,0,0,0,180,"See")
VILE ABCDEF 10 A_Wander
Loop
See:
VILE AABBCCDDEEFF 2 A_Chase (0,"Missile",CHF_FASTCHASE|CHF_RESURRECT) //A_VileChase
Loop
Missile:
VILE G 0 BRIGHT A_VileStart
VILE G 10 BRIGHT A_FaceTarget (0)
VILE H 8 BRIGHT A_VileTarget ("Distance_Resurrection")
VILE IJKLMN 8 BRIGHT A_FaceTarget (0)
VILE O 8 BRIGHT A_VileAttack
VILE P 20 BRIGHT
Goto See
Heal:
VILE "[\]" 10 BRIGHT
Goto See
Pain:
VILE Q 5
VILE Q 5 A_Pain
Goto See
Death:
VILE Q 7
VILE R 7 A_Scream
VILE S 7 A_NoBlocking
VILE TUVWXY 7
VILE Z -1
Stop
}
}

Spoiler: Custom Inventory to A_RadiusGive items to corpses

/*


http://zdoom.org/wiki/Classes:CustomInventory
*/
ACTOR Distance_Resurrection : CustomInventory
{
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
Inventory.Amount 0
Inventory.MaxAmount 0
Inventory.PickupMessage "LostSouls... EVERYWHERE!"

States
{
Spawn:
IFOG A 1
Loop
Pickup:
IFOG B 1 A_RadiusGive ("LostSoulBox",100,RGF_CORPSES,1)
Stop
Death:
IFOG E 1
Stop
}
}

Spoiler: Custom Inventory to spawn monsters in place of corpse

/*


http://zdoom.org/wiki/Classes:CustomInventory
http://zdoom.org/wiki/A_SpawnItemEx
http://zdoom.org/wiki/Thing_Raise
*/
ACTOR LostSoulBox : CustomInventory
{
+INVENTORY.QUIET
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
Inventory.Amount 0
Inventory.MaxAmount 0
//Inventory.PickupMessage "LostSouls... EVERYWHERE!"

States
{
Spawn:
IFOG A 1 A_SpawnItemEx ("LostSoul",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,256)
Stop //Loop
Pickup:
IFOG B 1 A_SpawnItemEx ("LostSoul",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,256)
Stop
Death:
IFOG E 1
Stop
}
}

[Vaecrius]

Just copy this exactly into a new DECORATE file and run it:

Code: Select all • Expand view

actor SuperArchvile : Archvile replaces Archvile
{
   states
   {
   heal:
      VILE "[\]" 10 bright A_RadiusGive("Raiser", 256, RGF_CORPSES|RGF_MONSTERS,1)
      goto see
   }
}

actor Raiser : CustomInventory
{
   states
   {
   pickup:
      TNT1 A 0 Thing_Raise(0)
      stop
   }
}

Then study it until you understand exactly what each line does, without thinking about anything that was done or considered in your or my previous attempts.

This is the simplest possible complete implementation of a mass resurrection.

[Arch]

Legacy of Suffering features mass ressurection, maybe you can get a clue:
http://www.doomworld.com/idgames/?id=15942

[Ravick]

If you just "heal" a corspe it will get health but wont get off of the Death state. (Its a pain to work with healer monsters, believe me )

You could use ACS as Arch and FDARI said. Or... a DECORATE kludge could be to spawn lots of 'shot-live' actors that moves with A_VileChase and A_Wander. They'd go healing neaby corpses, but each one per time. I dont know if it'd fit your needs however.

[Vaecrius]

I just noticed Thing_Raise doesn't have exactly the same effect as being raised by a monster: if you've got any special jump sequences in your monster's raise state, they appear to be ignored.

Good thing I didn't delete my previous response. ::copypasta::

[FDARI]

What does "special jump sequence" mean?
- goto
- wait, loop
- A_Jump...

It seems very strange that they should be ignored. Also, Thing_Raise "Resurrects the specified thing like an Arch-Vile does." So any difference is either a bug, or a documentation error.

[Vaecrius]

In isolation, this:

Spoiler:

Code: Select all • Expand view

actor UngibbableDoomImp : DoomImp replaces DoomImp
{
   states
   {
   XDeath:
      TNT1 A 0 A_GiveInventory("IsGibbed",1)
      goto Super :: XDeath
   Raise:
      TNT1 A 0 A_JumpIfInventory("IsGibbed",1,"RaiseGibbed")
      TROO ML 8
      TROO KJI 6
      goto See
   RaiseGibbed:
      TNT1 A 0 A_TakeInventory("IsGibbed",999)
      TROO TSR 8
      TROO QPON 6
      goto See
   }
}

actor IsGibbed : Inventory
{
   inventory.amount 1
   inventory.maxamount 1
}

...huh, now that I try it in isolation it works without a problem.

Probably something else that's messing with the effect then.

[RV-007]

Thank you FDARI and Vaecrius, now my (cultist) monster can raise other monsters from a distance (credits included in my edited rylayeh mod)! Muhahaha! The trick is that a monster actor uses A_VileTarget against target to spawn another monster. That spawned monster will (immediately) raise dead monsters w/i the target's vicinity. And they kept on rising! I feel the evil flowing thru me .
Here is the example code below:

Spoiler: Monster to start mass resurrection @ distance

/*
Archvile
blah
link

http://zdoom.org/wiki/Classes:Archvile
http://zdoom.org/wiki/A_LookEx
http://zdoom.org/wiki/A_Chase
http://zdoom.org/wiki/A_FaceTarget
*/
ACTOR ArchvileMonster : Archvile 64
{
Game Doom
SpawnID 111
Health 700
Radius 20
Height 56
Mass 500
Speed 15 //1.5
PainChance 10
MaxTargetRange 896
MONSTER
+QUICKTORETALIATE
+FLOORCLIP
+NOTARGET
+ALWAYSFAST
SeeSound "vile/sight"
PainSound "vile/pain"
DeathSound "vile/death"
ActiveSound "vile/active"
MeleeSound "vile/stop"
Obituary "%o was incinerated by an Archvile." //"$OB_VILE" //"%o was incinerated by an archvile."

States
{
Spawn:
VILE ABCDEF 10 A_LookEx (0,0,0,0,180,"See")
VILE ABCDEF 10 A_Wander
Loop
See:
VILE AABBCCDDEEFF 2 A_Chase (0,"Missile",CHF_FASTCHASE|CHF_RESURRECT) //A_VileChase
Loop
Missile:
VILE G 0 BRIGHT A_VileStart
VILE G 10 BRIGHT A_FaceTarget (0)
VILE H 8 BRIGHT A_VileTarget ("Skullvile")
VILE IJKLMN 8 BRIGHT A_FaceTarget (0)
VILE O 8 BRIGHT A_VileAttack
VILE P 20 BRIGHT
Goto See
Heal:
VILE "[\]" 10 BRIGHT
Goto See
Pain:
VILE Q 5
VILE Q 5 A_Pain
Goto See
Death:
VILE Q 7
VILE R 7 A_Scream
VILE S 7 A_NoBlocking
VILE TUVWXY 7
VILE Z -1
Stop
}
}

Spoiler: Spawned monster to raise dead monsters

/*
Skullvile
Skull of archvile
Like the archvile, except it can't really attack nor move.
n/a

http://zdoom.org/wiki/Classes:Archvile
http://zdoom.org/wiki/Classes:BossBrain
http://zdoom.org/wiki/A_LookEx
http://zdoom.org/wiki/A_Chase
http://zdoom.org/wiki/A_FaceTarget
http://www.zdoom.org/wiki/A_PlaySound
http://zdoom.org/wiki/A_RadiusGive
*/
ACTOR Skullvile //: Archvile 64
{
-SOLID
-SHOOTABLE
-PUSHABLE
+MISSILEEVENMORE
+MISSILEMORE
+STANDSTILL
+CANTLEAVEFLOORPIC
+NOINFIGHTING
+DONTMORPH
+NODAMAGE
+NOBLOOD
+STEALTH
+FLOORCLIP
+RANDOMIZE
-COUNTKILL
+NONSHOOTABLE
+ALWAYSFAST
+NOCLIP
-VULNERABLE

Game Doom
Speed 0
FastSpeed 0
Mass 10000000
MONSTER

States
{
Spawn:
SKVI ABC 10 A_LookEx (0,0,0,0,360,"Missile")
Loop
See:
SKVI AABBCC 2 A_Chase (0,"Missile",/*CHF_RESURRECT*/0) //A_VileChase
Loop
Missile:
SKVI D 0 BRIGHT A_PlaySound ("skullvile/attack",0,1.0,0,ATTN_NORM) //A_VileStart
SKVI D 10 BRIGHT A_FaceTarget (0)
SKVI E 8 BRIGHT A_RadiusGive ("HellRaiser",256,RGF_CORPSES|RGF_MONSTERS,1)
/*
SKVI D 8 BRIGHT A_FaceTarget (0)
SKVI D 8 BRIGHT A_VileAttack
SKVI CBA 20 BRIGHT
*/
Stop //Goto See
}
}

Spoiler: The dead rises around me!

/*
Hell Raiser
Skullvile's missile state into MASS RESURRECTION!
Great scene for Zombi - They Hunger :O
n/a

http://zdoom.org/wiki/Classes:CustomInventory
http://zdoom.org/wiki/Thing_Raise
*/
ACTOR HellRaiser : CustomInventory
{
States
{
Pickup:
TNT1 A 0 Thing_Raise (0)
Stop
}
}

[RV-007]

I also make somewhat of a mass A_VileAttack. No ground spike sprites though (don't care).

The Mass Vile Weapon!

Spoiler:

Code: Select all • Expand view

/*
RocketLauncher
The rocket launcher.
It fires projectiles which cause splash damage.
Not recommended for close range.
Uses rockets for ammo.
http://zdoom.org/wiki/Classes:RocketLauncher

Spaceship, Bobby, spaceship!

http://zdoom.org/wiki/Classes:RocketLauncher
http://zdoom.org/wiki/A_Print
http://zdoom.org/wiki/A_CheckReload
http://zdoom.org/wiki/A_FireMissile
http://zdoom.org/wiki/A_FireCustomMissile
http://zdoom.org/wiki/A_PlaySound
*/
ACTOR /*Vrock_Launcher*/ RocketLauncher : DoomWeapon 2003
{
   Game Doom
   SpawnID 29
   Weapon.SelectionOrder 2500
   Weapon.AmmoUse 1
   Weapon.AmmoGive 2
   Weapon.AmmoType "RocketAmmo"
   +WEAPON.NOAUTOFIRE
   Inventory.PickupMessage "You got the Vrock Launcher! Send 'em flying!" //"$GOTLAUNCHER" //"You got the rocket launcher!"
   
   Weapon.SlotNumber 5
   
   States
   {
      Ready:
         MISG A 1 A_WeaponReady
         Loop
      Deselect:
         MISG A 1 A_Lower
         Loop
      Select:
         //MISG A 1 A_Raise
         MISG A 0 A_Print ("Vrock Launcher Equipped!")
         Goto Selection_Confirmed //Loop
      Selection_Confirmed:
         MISG A 1 A_Raise
         Loop
      Fire:
         MISG B 0 A_CheckReload
         MISG B 8 A_GunFlash
         MISG B 12 A_FireCustomMissile ("Vrock",0,1,0,0,1,0) //A_FireMissile
         MISG B 0 A_ReFire
         Goto Ready
      Flash:
         MISF A 3 Bright A_Light1
         MISF B 4 Bright
         MISF CD 4 Bright A_Light2
         Goto LightDone
      Spawn:
         LAUN A -1
         Stop
   }
}

The Vile-Rocket (oh snuggles!):

Spoiler:

Code: Select all • Expand view

/*
Rocket
The projectile fired from a player's rocket launcher or a cyberdemon.
The second-most powerful projectile in Doom.
http://zdoom.org/wiki/Classes:Rocket

3, 2, 1, silence reigns the air.

http://zdoom.org/wiki/Classes:Rocket
http://zdoom.org/wiki/A_Explode
http://zdoom.org/wiki/A_Quake
http://zdoom.org/wiki/A_RadiusGive
*/
ACTOR Vrock //: Rocket
{
   Game Doom
   SpawnID 127
   Radius 11
   Height 8
   Speed 20
   Damage 20
   Projectile
   +RANDOMIZE
   +DEHEXPLOSION
   +ROCKETTRAIL
   SeeSound "weapons/rocklf"
   DeathSound "weapons/rocklx"
   Obituary "%o can't liftoff from %k's vrock." //"$OB_MPROCKET" //"%o rode %k's rocket."
 
   States
   {
      Spawn:
         MISL A 1 Bright
         Loop
      Death:
         MISL B 0 A_Quake (1,20,0,256,"world/quake")
         MISL B 8 Bright A_RadiusGive ("Vrock_Radius",256,RGF_GIVESELF|RGF_PLAYERS|RGF_MONSTERS|RGF_OBJECTS|RGF_CORPSES,1) //A_Explode
         MISL C 6 Bright
         MISL D 4 Bright
         Stop
   }
}

Dangerous Radius for ThrustThingZ and A_Explode (vrock projectile damage still works for +BOSS monsters)

Spoiler:

Code: Select all • Expand view

/*
ArchvileFire
The temporary flame sprite which follows an Archvile's target while it attacks.
Note that this actor does not shoot other actors or players in the air.
For that use A_VileAttack.
http://zdoom.org/wiki/Classes:ArchvileFire

http://zdoom.org/wiki/Classes:CustomInventory
http://zdoom.org/wiki/Classes:ArchvileFire
http://zdoom.org/wiki/Classes:BossBrain
http://zdoom.org/wiki/A_VileAttack
http://zdoom.org/wiki/ThrustThingZ
http://zdoom.org/wiki/A_Explode
*/
ACTOR Vrock_Radius : CustomInventory
{
   RenderStyle "None"

   States
   {
      Pickup:
         PUFF E 1 ThrustThingZ (0,70,0,1)
         PUFF E 0 A_Explode (70,70,1,1,0,0,0)
         Stop
   }
}