Random Editing Questions

[amv2k9]

Eh, it's still not working. I removed the semicolons from the if statements and added in a 1-tic delay right before the last restart.

[FDARI]

Maybe you should print PLAYER_TID to verify it. You didn't try to set the player's tid in the map editor, did you? (The tid of the startspot doesn't affect the tid of the spawned player, you must set it in script)

Besides, in an enter-script you should be using tid 0 for efficiency and simplicity, as well as CheckInventory rather than CheckActorInventory. (Roughly same as CheckActorInventory with tid 0)

Another discovery: You'll never get anything but less than 40 the way your checks are organised. Whenever the value is less than 30, it will already have triggered and restarted at "less than 40". You'll need to reverse them if you want to use that approach. (Check for less than 10 first, then less than 20...)

Spoiler: My own version

I'm a big user of switches. Using a series of if-statements is perfectly fine as well.

Code: Select all • Expand view

#library "heart"
#include "zcommon.acs"

script 823 enter
{
    if(CheckInventory("Satanic_LowHealthIndicatorCheck")) // <----
    {    
      switch ( GetActorProperty(0, APROP_HEALTH) / 10 )
      // dividing health by 10 gives you a specific integer for each 10 points
      // of health, making a switch-statement feasible
      {
       case 3: // range 30 - 39 divided by 10
         LocalAmbientSound("misc/djump", 127);
         delay(35*4);         
         restart;
       case 2: // range 20 - 29 divided by 10
         LocalAmbientSound("misc/djump", 127);
         delay(35*3);
         restart;
       case 1: // range 10 - 19 divided by 10
         LocalAmbientSound("misc/djump", 127);
         delay(35*2);
         restart;
       case 0: // range 0 - 9 divided by 10
         LocalAmbientSound("misc/djump", 127);
         HUDMessage(s:"health<10";HUDMSG_PLAIN,114,CR_GRAY,160.0,80.0,0);
         delay(35);
         restart;
      }
   }
   Delay(1); // <---- Don't forget this as well...
   restart;
}

If you're loading it as a library, don't forget the loadacs lump.

[amv2k9]

Maybe you should print PLAYER_TID to verify it. You didn't try to set the player's tid in the map editor, did you? (The tid of the startspot doesn't affect the tid of the spawned player, you must set it in script)

No, I didn't set the player's tid in a map editor. Other scripts use PLAYER_TID and work just fine... But I'll try that just in case.

Besides, in an enter-script you should be using tid 0 for efficiency and simplicity, as well as CheckInventory rather than CheckActorInventory. (Roughly same as CheckActorInventory with tid 0)

CheckInventory would work okay with this? I didn't think it would, since its an enter-type script.

Another discovery: You'll never get anything but less than 40 the way your checks are organised. Whenever the value is less than 30, it will already have triggered and restarted at "less than 40". You'll need to reverse them if you want to use that approach.(Check for less than 10 first, then less than 20...)

Yeah, I thought this had to be set up like how you would check for inventory in DECORATE; you check for the largest at-least value first.

Spoiler: My own version

I'm a big user of switches. Using a series of if-statements is perfectly fine as well.

Thanks a lot for this! I'll be sure to study it so I can correct these kind of things earlier in the future

[FDARI]

"No, I didn't set the player's tid in a map editor. Other scripts use PLAYER_TID and work just fine... But I'll try that just in case."
Slightly confusing. What did you do to set the player's tid? Perhaps you did not do anything. PLAYER_TID is just the name of a variable, or a number. You create that number, and you provide its actual meaning. To make it meaningful for your purpose, you must cause the player to have PLAYER_TID as its tid. However, you don't need to use it at all as long as you know the script is activated by the player. (ENTER is always activated by each player.)

Use TID 0 in functions that support it.
Use functions that affect the activator where there are multiple variants. (CheckInventory, CheckActorInventory)

Decorate versus ACS (check order): -- Do not worry if this confuses you, it is somewhat poorly worded --
A_JumpIfInventory("item", x, "state") compares to if (CheckInventory("x) >= x) { SetActorState(0, "state", false); }
Note: The check is variable >= control_value, not variable < control_value. When you are checking for greater values, using the lowest threshold first makes the higher thresholds irrelevant. When checking for smaller values, using the highest threshold first makes the lower thresholds irrelevant. Any occurence that could trigger a later condition, will also trigger the very first condition. Decorate inventory checks do not allow you to check for less inventory, only equal/more.

Spoiler: Read if the above was confusing

Wrong if-order for less-than checks

Code: Select all • Expand view

x = 40;
// x would need to be declared as an int somewhere. For these examples, assume x is an existing variable.
if (x < 40) { terminate; } // not gonna happen, x is 40, not less
if (x < 30) { terminate; } // not gonna happen, same reason
if (x < 1) { terminate; } // not gonna happen, same reason

Wrong if-order for less-than checks

Code: Select all • Expand view

x = 0;
if (x < 40) { terminate; } // happens, 0 is less than 40
if (x < 30) { terminate; } // not gonna happen, script terminated
if (x < 1) { terminate; } // not gonna happen, script terminated

Correct order

Code: Select all • Expand view

x = 0;
if (x < 1) { terminate; } // happens, 0 is less than 1
if (x < 30) { terminate; } // not gonna happen, script terminated (0 is less than 30)
if (x < 40) { terminate; } // not gonna happen, script terminated (0 is less than 40)

Code: Select all • Expand view

x = 1;
if (x < 1) { terminate; } // not gonna happen, 1 is not less than 1
if (x < 30) { terminate; } // happens, 1 is less than 30
if (x < 40) { terminate; } // not gonna happen, script terminated (1 is less than 40)

And just a couple of >= examples as well (applying equally to > examples). Wrong order (would be right if we were checking x < CONTROL_VALUE):

Code: Select all • Expand view

x = 0;
if (x >= 1) { terminate; } // not gonna happen, 0 is less than 1
if (x >= 10) { terminate; } // not gonna happen, 0, is less than 10

Code: Select all • Expand view

x = 20;
if (x >= 1) { terminate; } // happens, 20 >= 1
if (x >= 10) { terminate; } // not gonna happen, script terminated

Correct order:

Code: Select all • Expand view

x = 20;
if (x >= 10) { terminate; } // happens, 20 >= 10
if (x >= 1) { terminate; } // not gonna happen, script terminated

Code: Select all • Expand view

x = 5;
if (x >= 10) { terminate; } // not gonna happen, 5 is less than 10
if (x >= 1) { terminate; } // happens, 5 >= 1

[amv2k9]

Thanks for the help, FDARI!

ALrighty, next question:

I'm making a weapon that launches multiple remote-detonated stickymines. Basically how it works right now is the mine has +SEEKERMISSILE, and its death state is a loop where it alternates between checking for a token item held by the player (if true, it then jumps to a state where it explodes) and calling A_Fire, which allows it to "adhere" to a monster's collison box. The problem is... this weapon fires multiple mines, and when you fire them at a monster, even if only some of them would impact the monster, they ALL adhere to the monster, in the same spot. At first I thought some of them were disappearing, but that appears to not be the case; I did a little test where the mines had dynamic lights. The resulting dynamic light was very strong and had a very fine edge instead of fading out slowly, telling me all the dynamic lights were in the same xyz coordinates in relation to the monster's collison box.

...So, can I get these mines to adhere to different places on a monster's collison box?

[FDARI]

I'd check out A_Warp, which is written to be a general purpose A_Fire. If you store an angle in a user variable on the mine, you should be able to warp the sticky mine to a specific position on the victim. A_Warp will not determine the correct distance from the monster, though, so you might have to make an initial A_Fire call to get into position, if that function knows a monster's radius.

A fully functional thing isn't the simplest, so I'll provide a potentially helpful code fragment.

Spoiler: It could might work

Code: Select all • Expand view

actor StickyMineExcerpt
{
    var int user_a;
    var int user_b;
    var int user_c;

    states
    {
    // This code assumes that a_fire will put the mine at the proper distance, and that the distance is not already known
    // A_Fire is here used to pick distance and relative height to the target; removing these calculations simplifies the actor

        attach: // when triggered, attach to monster; assumed "target" based on A_Fire
            bomb a 0 a_fire // get in position
            bomb a 0 a_setuservar("user_a", x) // store original a_fire coordinates for distance calculation
            bomb a 0 a_setuservar("user_b", y)
            bomb a 0 a_setuservar("user_c", z) // height is not stored for distance
            bomb a 0 a_warp(AAPTR_TARGET,  0,0,0,   0,  WARPF_NOCHECKPOSITION) // Warp to target location to get its coordinates
            bomb a 0 a_setuservar("user_a",  sqrt( (user_a-x) * (user_a-x) + (user_b-y) * (user_b-y))) // distance between (user_a,user_b) and (x,y); distance from target
            bomb a 0 a_setuservar("user_b", random(0,359)) // random angle relative to monster
         stick: // when all stickiness is determined, hang on
           // user_a: distance; user_b: angle; user_c: z-distance
            bomb a 1 a_warp(AAPTR_TARGET, user_a, 0, user_c, user_b, WARPF_NOCHECKPOSITION | WARPF_COPYINTERPOLATION)
            loop

            // stick just runs forever here. you'd put the a_warp in place of a_fire and keep whatever makes stuff happen
    }
}

[amv2k9]

Actually, I remembered about A_Warp a while after I made that post, and I got it working! But this code you gave me looks very interesting as well. I'll have to give it a shot. Thanks!

[amv2k9]

For something I'm working on, I need an action function that jumps if the player has the calling actor in view within a specified FOV cone. Now, I already looked at A_JumpIfTargetInLOS and A_JumpIfInTargetLOS, and unless I'm reading them wrong, these aren't what I need. Anyone able to clarify?

[NeuralStunner]

I don't even know what you just said, so I can't say for sure unless you give a step-by-step of what you're looking for.

[amv2k9]

Lemme see if I can explain it better.

Basically, this is for weapon pickups that, when you're close enough and looking directly at it (or within a couple of degrees of directly), spawn an actor above the pickup, telling you the weapon properties. Once you're looking away, that window goes away.

Like this:
http://i.ytimg.com/vi/_y3QkAKmAhU/0.jpg

[FDARI]

I think you may need to go this route:

Code: Select all • Expand view

actor BaseNotifyPickup : Inventory // You may want to inherit from CustomInventory for greater flexibility
{
    var int user_pnum;

    states
    {
        spawn: // you should provide a different spawn state
            tnt1 a 1
        checkNextPlayer:
            "####" "#" 0 A_RearrangePointers(AAPTR_PLAYER1<<user_pnum)
            "####" "#" 0 A_SetUserVar("user_pnum", (user_pnum < 7) * (user_pnum + 1))
            "####" "#" 0 A_JumpIfTargetInLOS("notify", 9, JLOSF_TARGETLOS|JLOSF_DEADNOJUMP) // deadnojump isn't required, max distance isn't specified, fov is 9 degrees
            "####" "#" 0 A_JumpIf(true, "spawn")
        notify:
            "####" "#" 0 a_spawnitemex("defaultNotificationActorIfYouHaveOne_orMaybeYouWouldNotDefineThisStateInTheBaseActor")
            "####" "#" 0 A_JumpIf(true, "spawn")
            stop     
    }
}

Code: Select all • Expand view

actor ExampleNotifyPickup : BaseNotifyPickup
{
    states
    {
        notify:
           "####" "#" 0 a_custommissile("notifyExample") // There are many ways to spawn an actor; this is just provided as an alternate suggestion
        spawn:
            ITEM A 1 A_JumpIf(user_pnum, "checkNextPlayer") // First spawn: No action. Later iterations: Check players 2-8 and then wait 1 tick
            goto checkNextPlayer // check player 1, which will eventually return to the spawn state
    }
}

actor LaxNotifyPickup : BaseNotifyPickup
{
    states
    {
        notify:
            "####" "#" 0 a_facetarget
            "####" "#" 0 a_spawnitemex("laxNotifier") // this is the function I think you'll be using
        spawn:
            ITEM B 1
            goto checkNextPlayer // check 1 player every tick
    }
}

ExampleNotifyPickup checks all players every tick (except for the very first one), while LaxNotifyPickup checks one player each tick (not the first one), repeating each player every 8 ticks. There is only one state with a non-0 duration here. That duration must be at least 1, but can be higher. Whatever delay you set here will be between each player (Lax) or between each check of all players (the first example).

Does this work?

[amv2k9]

I'll have to give this a try. Thanks a lot!

See the thing was is, I wasn't sure if inventory actors have the player as their target. Hence the confusion over what action function I'd need.

[amv2k9]

Where is Strife's base HUD defined? I looked in the sbarinfo folder, and there isn't a file for it. Then I looked through the Strife IWAD, thinking that it might be defined there (like part of Hexen's is) but it's not there either. I'm trying to make new versions of the dropdown questlog, keys and stats windows that Strife has.

[ChronoSeth]

IIRC, it's not defined. SBARINFO isn't quite flexible enough to do everything that the HUD does yet.

[amv2k9]

Having a problem with a friendly monster in a project I'm working on. I've narrowed it down to the following; if the monster is killed when its in an attack state, it crashes the game. I've tried some tweaks to the code, but nothing seems to solve the problem.

Spoiler:

Code: Select all • Expand view

Melee:
   TNT1 A 0 A_TakeInventory("TargetTimer",255)
   TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
   STLK L 5 A_FaceTarget
   TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
   STLK M 3 BRIGHT A_CustomMeleeAttack(3,"stalker/attack","none")
   STLK N 0 A_Look
   TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
   STLK N 5 A_FaceTarget
   Goto See
Death:
   TNT1 A 0 A_TakeInventory("SpiderbotPained",1,0,AAPTR_PLAYER1)
   TNT1 A 0 A_TakeInventory("SpiderDeployed",1,0,AAPTR_PLAYER1)
   TNT1 A 0 A_TakeInventory("SpiderDetonate",1,0,AAPTR_PLAYER1)
   STLK O 4
   STLK P 4 A_Scream
   STLK QRST 4 BRIGHT
   STLK U 4 BRIGHT A_NoBlocking
   STLK VW 4 BRIGHT
   STLK XXXX 1 BRIGHT
   TNT1 A 0 A_SpawnItemEx("SmallXplosionNoNails")
   Stop

Here's the whole actor entry:

Spoiler:

Code: Select all • Expand view

ACTOR Spiderbot : Stalker
{
   Health 80
   Painchance 256
   Speed 20
   Radius 20
   Height 20
   Monster
   -NOGRAVITY
   -SPAWNCEILING
   +FRIENDLY
   +NOBLOOD
   +LOOKALLAROUND
   +MOVEWITHSECTOR
   Scale "0.75"
   Translation "160:175=[166,166,205]:[38,38,99]",
            "176:191=[30,30,91]:[00,00,04]",
            "192:207=[180,180,205]:[72,72,99]",
            "208:223=[64,64,91]:[00,00,04]"
   States
   {
   Spawn:
      TNT1 A 0
      TNT1 A 0 A_TakeInventory("WOR2Capsules",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_GiveInventory("SpiderDeployed",1,AAPTR_PLAYER1)
   SpawnLoop:
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      TNT1 A 0 A_JumpIfInventory("TargetTimer",255,"RemoveAndSpawnCapsule")
      TNT1 A 0 A_GiveInventory("TargetTimer",1)
      STLK J 1 A_Look
      Loop
   See:
      TNT1 A 0 A_JumpIfInventory("TargetTimer",255,"RemoveAndSpawnCapsule")
      TNT1 A 0 A_GiveInventory("TargetTimer",1)
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK J 4 A_StalkerWalk
      TNT1 A 0 A_JumpIfInventory("TargetTimer",255,"RemoveAndSpawnCapsule")
      TNT1 A 0 A_GiveInventory("TargetTimer",1)
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK K 4 A_Chase
      TNT1 A 0 A_JumpIfInventory("TargetTimer",255,"RemoveAndSpawnCapsule")
      TNT1 A 0 A_GiveInventory("TargetTimer",1)
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK L 4 A_StalkerWalk
      Loop
   Melee:
      TNT1 A 0 A_TakeInventory("TargetTimer",255)
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK L 5 A_FaceTarget
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK M 3 BRIGHT A_CustomMeleeAttack(3,"stalker/attack","none")
      STLK N 0 A_Look
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK N 5 A_FaceTarget
      Goto See
   Pain:
      TNT1 A 0 A_GiveInventory("SpiderbotPained",1,AAPTR_PLAYER1)
      TNT1 A 0 A_JumpIfInventory("SpiderDetonate",1,"Detonate",AAPTR_PLAYER1)
      STLK L 1 A_Pain
      STLK L 1
      TNT1 A 0 A_TakeInventory("SpiderbotPained",1,0,AAPTR_PLAYER1)
      Goto See
   Detonate:
      TNT1 A 0 A_Die
   Death:
      TNT1 A 0 A_TakeInventory("SpiderbotPained",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_TakeInventory("SpiderDeployed",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_TakeInventory("SpiderDetonate",1,0,AAPTR_PLAYER1)
      STLK O 4
      STLK P 4 A_Scream
      STLK QRST 4 BRIGHT
      STLK U 4 BRIGHT A_NoBlocking
      STLK VW 4 BRIGHT
      STLK XXXX 1 BRIGHT
      TNT1 A 0 A_SpawnItemEx("SmallXplosionNoNails")
      Stop
   XDeath:
      TNT1 A 0 A_TakeInventory("SpiderbotPained",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_TakeInventory("SpiderDeployed",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_TakeInventory("SpiderDetonate",1,0,AAPTR_PLAYER1)
      STLK O 4
      STLK P 4 A_Scream
      STLK QRST 4 BRIGHT
      STLK U 4 BRIGHT A_NoBlocking
      STLK VW 4 BRIGHT
      STLK XXXX 1 BRIGHT
      TNT1 A 0 A_SpawnItemEx("SmallXplosionNoNails")
      Stop
   Death.Remove:
      TNT1 A 0 A_TakeInventory("SpiderDeployed",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_TakeInventory("SpiderDetonate",1,0,AAPTR_PLAYER1)
      TNT1 A 1
      Stop
   RemoveAndSpawnCapsule:
      TNT1 A 0 A_TakeInventory("SpiderbotPained",1,0,AAPTR_PLAYER1)
      TNT1 A 0 A_SpawnItemEx("NoTargetsMessage",0,0,30)
      STLK J 70
      TNT1 A 0 A_NoBlocking
      TNT1 A 0 A_SpawnItemEx("CapsuleSmoke")
      TNT1 A 0 A_SpawnItemEx("RecoveredSpiderbotCapsuleGiver")
      TNT1 A 0 A_Die("Remove")
      TNT1 A 1
      Stop
   }
}