The "How do I..." Thread

[Blue Shadow]

Edit: New problem I can't figure out for the life of me.

The name of the sound file should be withen 8-character length. Yours is 9-character long (DBSHOTGN1).

Edit:

Does gzdoom leave a log of issues after each run? That would be realllly helpful.

Run (G)ZDoom from the command line like this:

Code: Select all • Expand view

gzdoom +logfile console.txt

Tried that, it clips through everything that way, monsters included (so no damage dealt).

There's the NOCLIP and NOINTERACTION flags that will make your projectile goes through walls and such, however, using these flags will make the projectile excluded from collision detecton completely, thus making it incapable of damaging actors.

In other words, there isn't a way of doing that, as far as I know.

[Zombieguy]

How do I flip a weapon sprite?

Anyone, please?

[Blue Shadow]

In Slade, highlight the graphic(s) in question and from the main menu bar, click on the Graphic. You've got Mirror, Flip, and Rotate options if you want.

[Zombieguy]

Thanks.

[NickPerrin]

The name of the sound file should be withen 8-character length. + Run (G)ZDoom from the command line like this...

Big thumbs up on both counts, thanks. The wiki for SNDINFO didn't say anything about character lengths.

Random question, any mods/wads anyone can think of that have very unique/different main menus (on exe start)? I'm interested in seeing how far this functionality can be pushed. Been messing around with titlemap but there's gotta be more aside from that than simply changing xy menu offsets...?

[Zombieguy]

I'm working with reloading sequences, and everything works, but, when my pistol runs completely out of ammo, it auto de-selects itself.

Spoiler: What am I doing wrong?

Code: Select all • Expand view

Actor Handgun : Pistol replaces Pistol
{
   decal bulletchip
   //Weapon.SelectionOrder 200
   Weapon.AmmoType1 "PISClip"
    Weapon.AmmoType2 "Clip"
    Weapon.AmmoGive 50
    Weapon.AmmoGive2 10
    Weapon.AmmoUse 1
   States
   {
   Ready:
      PKPI A 1 A_WeaponReady
      PKPI A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      Loop
   Deselect:
      PKPI A 1 A_Lower
      Loop
   Select:
      PKPI A 1 A_Raise
      Loop
   Fire:
       TNT1 A 0 A_JumpIfNoAmmo("Reload")
      PKPI A 4
      PKPI B 2 A_FirePistol
      //TNT1 A 0 A_FireCustomMissile("RedFlareSpawn",0,0,0,0)
      //TNT1 A 0 BRIGHT A_FireCustomMissile("EnBulletPuff",frandom(-1.4,1.4),0)
       PKPI A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-2)
      PKPI A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-2)
      PKPI B 2 A_SetPitch(pitch-0.6)
      PKPI CCE 1 A_SetPitch(pitch+0.2)
      //PKPI CEDB 2
      PKPI E 1
      PKPI DB 2
      PKPI A 5 A_ReFire
      Goto Ready
   Reload:
        PISG A 0 A_JumpIfInventory("PISClip",10,16)
        PISG A 0 A_JumpIfInventory("Clip",1,1)
        Goto Ready
        PISG H 5
        PISG J 6
        PISG J 6 A_PlayWeaponSound("weapons/Pout")
        PISG J 3 A_FireCustomMissile("Clip1",180,0,10,3)
        PISG J 6
        PISG I 6 A_PlaySound("weapons/M91")
        PISG A 0 A_TakeInventory("Clip",1)
        PISG A 0 A_GiveInventory("PISClip",1)
        PISG A 0 A_JumpIfInventory("PISClip",10,2)
        PISG A 0 A_JumpIfInventory("Clip",1,6)
        PISG H 6
        PISG K 7
        PISG G 7 A_PlayWeaponSound("weapons/M94")
        PISG F 5
        PISG A 0
        goto Ready
        PISG A 0
        Goto Reload+8
      //Stop
     Flash:
         PISG E 0 A_FireCustomMissile("9mmCasingSpawner",0,0,8,-4)
        PKPF A 3 Bright A_Light1
        TNT1 A 2 A_Light1
        Goto LightDone
     }
  }


[Blue Shadow]

Hmm, try WEAPON.AMMO_OPTIONAL flag.

[Zombieguy]

You mean, +AMMO_OPTIONAL? It works, thanks!

[Zombieguy]

One more thing:

The shotgun works, but when the gun has all eight shells loaded in the chamber, or when it doesn't require to be reloaded, it draws frames of the gun I don't want it to draw. It looks, odd.

Spoiler: :D

Code: Select all • Expand view

Actor PerkShotgun : Shotgun replaces Shotgun
{
   decal bulletchip
   Weapon.AmmoType1 "ShotgunShell"
    Weapon.AmmoType2 "Shell"
    Weapon.AmmoGive 0
    Weapon.AmmoGive2 8
    Weapon.AmmoUse 1
    Weapon.Kickback 200
   +AMMO_OPTIONAL
   States
   {
   Ready:
      PKSG A 1 A_WeaponReady
      PKSG A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      Goto Ready
   Fire:
       TNT1 A 0 A_JumpIfNoAmmo("Reload")
      PKSG A 3
      //TNT1 A 0 A_FireCustomMissile("RedFlareSpawn",0,0,0,0)
      //TNT1 A 0 A_FireCustomMissile("RedFlareSpawn",0,0,0,0)
      PKSG A 5 A_FireShotgun
      //TNT1 A 0 BRIGHT A_FireCustomMissile("EnBulletPuff",frandom(-1.4,1.4),0)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKS2 A 0 A_FireCustomMissile("SmokeSpawner1",0,0,-1,-5)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKS2 A 0 A_FireCustomMissile("SmokeSpawner1",0,0,-1,-5)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKSG B 2
      PKSG C 1
      PKSG D 2
      PKSG E 3
      PKSG F 4
      PKSG O 0 A_FireCustomMissile("ShotgunCasingSpawner",0,0,-20,-16)
      PKSG G 1
      PKSG H 3
      PKSG GFEDCB 2
      PKSG A 1
      PKSG A 7 A_ReFire
      Goto Ready
   Reload:
      SHTG A 0 A_JumpIfInventory("ShotgunShell",8,26)
      SHTG A 0 A_JumpIfInventory("Shell",1,1)
      Goto Ready
      SHTG A 2 A_WeaponReady
      SHTG BC 4
      SHTR I 2
      SHTR H 6 A_WeaponReady
      SHTR ABCD 1
      SHTR E 0 A_TakeInventory("Shell",1)
      SHTR E 0 A_GiveInventory("ShotgunShell",1)
      SHTR E 1 A_PlayWeaponSound("weapons/shotgunin")
      SHTR F 3
      SHTR E 2
      SHTR G 1
      SHTR H 0 A_JumpIfInventory("ShotgunShell",8,2)
      SHTR H 0 A_JumpIfInventory("Shell",1,9)
      SHTR H 6
      SHTR J 4 A_PlayWeaponSound("weapons/shotguncock")
      //SHTR H 4
      //SHTR I 2
      //SHTG CB 4
      //SHTG A 4
      //SHTG A 0
     //PKSG GFEDCB 2
     PKSG GFEDCB 2
      goto Ready
      SHTR A 0
      Goto Reload+6
   Flash:
      SHTF B 3 Bright A_Light2
      SHTF A 2 Bright A_Light1
      Goto LightDone
   }
}

ACTOR ShotgunShell : Ammo
{
Inventory.MaxAmount 8
Ammo.BackpackAmount 0
Ammo.BackpackMaxAmount 8
Inventory.Icon SHOTA0
}



[Blue Shadow]

Okey, I've made few adjustments that I believe could fix the problem, however, I can't make for sure whether it's really fixed or not, since I don't have the sprites to test the weapon in game.

Spoiler:

Code: Select all • Expand view

Actor PerkShotgun : Shotgun replaces Shotgun
{
   decal bulletchip
   Weapon.AmmoType1 "ShotgunShell"
    Weapon.AmmoType2 "Shell"
    Weapon.AmmoGive 0
    Weapon.AmmoGive2 8
    Weapon.AmmoUse 1
    Weapon.Kickback 200
   +AMMO_OPTIONAL
   States
   {
   Ready:
      PKSG A 1 A_WeaponReady
      PKSG A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      Goto Loop
   Fire:
      TNT1 A 0 A_JumpIfNoAmmo("Reload")
      PKSG A 3
      //TNT1 A 0 A_FireCustomMissile("RedFlareSpawn",0,0,0,0)
      //TNT1 A 0 A_FireCustomMissile("RedFlareSpawn",0,0,0,0)
      PKSG A 5 A_FireShotgun
      //TNT1 A 0 BRIGHT A_FireCustomMissile("EnBulletPuff",frandom(-1.4,1.4),0)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKS2 A 0 A_FireCustomMissile("SmokeSpawner1",0,0,-1,-5)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKS2 A 0 A_FireCustomMissile("SmokeSpawner1",0,0,-1,-5)
      PKSG A 0 A_FireCustomMissile("SmokeSpawner1",0,0,0,-5)
      PKSG B 2
      PKSG C 1
      PKSG D 2
      PKSG E 3
      PKSG F 4
      PKSG O 0 A_FireCustomMissile("ShotgunCasingSpawner",0,0,-20,-16)
      PKSG G 1
      PKSG H 3
      PKSG GFEDCB 2
      PKSG A 1
      PKSG A 7 A_ReFire
      Goto Ready
   Reload:
      SHTG A 0 A_JumpIfInventory("ShotgunShell", 0, "Ready") // Putting zero as amount would make it check to see if the weapon is fully loaded regardless of the size of the "clip"
      SHTG A 0 A_JumpIfInventory("Shell", 1, 1)
      Goto Ready
      SHTG A 2 A_WeaponReady
      SHTG BC 4
      SHTR I 2
      // Intentional fall through
  ReloadLoop:
      SHTR H 6 A_WeaponReady
      SHTR ABCD 1
      SHTR E 0 A_TakeInventory("Shell",1)
      SHTR E 0 A_GiveInventory("ShotgunShell",1)
      SHTR E 1 A_PlayWeaponSound("weapons/shotgunin")
      SHTR F 3
      SHTR E 2
      SHTR G 1
      SHTR H 0 A_JumpIfInventory("ShotgunShell", 0, "FinishReload")
      SHTR H 0 A_JumpIfInventory("Shell", 1, "ReloadLoop")
      // Intentional fall through
  FinishReload:
      SHTR H 6
      SHTR J 4 A_PlayWeaponSound("weapons/shotguncock")
      //SHTR H 4
      //SHTR I 2
      //SHTG CB 4
      //SHTG A 4
      //SHTG A 0
      //PKSG GFEDCB 2
      PKSG GFEDCB 2
      goto Ready
   Flash:
      SHTF B 3 Bright A_Light2
      SHTF A 2 Bright A_Light1
      Goto LightDone
   }
}


[Zombieguy]

Code: Select all • Expand view

Ready:
      PKSG A 1 A_WeaponReady
      PKSG A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      //Goto Loop <--- nope :D
      Goto Ready <--- yes


Thanks Blue Shadow. It works perfectly! And, I don't blame you for making that mistake there. Besides, you didn't have the sprites. So, .

[Blue Shadow]

Silly me, it should only be "Loop" and not "Goto Loop".

Using "Goto Ready" or "Loop" in that case is pretty much the same. I only used it because it makes the code look a little bit more professional, if you know what I mean.

[Sgt Dopey]

How do I make palette translation?

[Blue Shadow]

Translation

[NickPerrin]

Hey. Can't seem to find anything pertaining to this in the wiki.

How do I make a non-automatic weapon or fire mode? As in, you can't simply hold down the button to keep firing, but must press it each time you want to shoot.