[Fixed] +FLOATBOB backwards-compatibility

[Enjay]

What it seems is really needed is a physical bob of some sort that doesn't allow an actor to sink into the floor/ceiling (unless it has nointeraction or similar I suppose - ie it respects the collision settings of the actor), which pauses when the game is paused by any means and, ideally, has parameters to allow altering of the amplitude and frequency of the bob. However, given the problems that the original floatbob caused, I suspect that coding such a thing is not particularly easy to make sure all eventualities are covered.

[Blzut3]

Not really, we can continue to insert code to add the bob height to anything that returns the Z height until all instances are fixed (either by fixing them preemptively or waiting until an example of something broken is produced).

I think the worst case scenario is some compatibility option would be needed to restore the original behavior, but I doubt there's anything that can't be fixed with the before mentioned method.

[Graf Zahl]

Ugh...

No more workarounds, please. While I understand that floatbobbing was essentially broken the current 'solution' to break every mod that uses a floatbobbing monster is clearly not acceptable. There must be a fallback option - at least for solid/shootable things that doesn't involve tinkering with the DECORATE code.

The Afrit is somewhat broken right now. Period. And that breaks lots of existing maps.

[randi]

The Afrit is somewhat broken right now. Period. And that breaks lots of existing maps.

The Afrit doesn't even use floatbob, so how is it relevant or broken? To save time, here is its decorate:

Spoiler: afrit.wad:DECORATE

Code: Select all • Expand view

Actor Afrit
{
  Health 800
  Speed 6
  Radius 24
  Height 72
  PainChance 50
  Mass 500
  SeeSound "Baron/Sight"
  PainSound "Baron/Pain"
  DeathSound "Baron/Death"
  ActiveSound "Baron/Active"
  Monster
  +NoGravity
  +NoBlood
  +Float
  +DontHurtSpecies
  Obituary "%o was scorched by an Afrit"
  HitObituary "%o found the Afrit too hot to handle."
  Damagefactor "HellFire", 0.0
  States
  {
  Spawn:
    FRIT A 0
    FRIT A 0 A_CustomMissile("OrbitComet", 44, 0, 0, 2, 0)
    FRIT A 0 A_CustomMissile("OrbitComet2", 44, 0, 180, 2, 0)
    FRIT AABB 4 Bright A_Look
    Goto Spawn+3
  Idle:
    FRIT ABCD 4 Bright A_Look
    Loop
  See:
    FRIT AABBCCDD 2 Bright A_Chase
    Loop
  Melee:
    TNT1 A 0 A_Jump(64, "Melee2")
    FRIT ST 6 Bright A_FaceTarget
    FRIT U 6 Bright A_CustomComboAttack("AfritBall", 44, 10, "Baron/Melee")
    Goto See
  Melee2:
    FRIT E 6 Bright A_FaceTarget
    FRIT F 6 Bright A_CustomMissile("HellFire", 44)
    FRIT G 6 Bright A_FaceTarget
    Goto See
  Missile:
    TNT1 A 0 A_Jump(64, "Missile3")
    TNT1 A 0 A_Jump(128, "Missile2")
    FRIT ST 6 Bright A_FaceTarget
    FRIT U 6 Bright A_CustomComboAttack("AfritBall", 44, 10, "Baron/Melee")
    Goto See
  Missile2:
    FRIT EF 6 Bright A_FaceTarget
    FRIT G 6 Bright A_CustomMissile("Comet", 44)
    Goto See
  Missile3:
    FRIT E 6 Bright A_FaceTarget
    FRIT F 6 Bright A_CustomMissile("Hellfire", 44)
    FRIT G 6 Bright A_FaceTarget
    Goto See
  Pain:
    FRIT H 4 Bright
    FRIT H 4 Bright A_Pain
    Goto See
  Death:
    TNT1 A 0 A_NoGravity
    FRIT I 6 Bright A_Scream
    FRIT J 5 Bright A_NoBlocking
    FRIT KLMNOPQR 4 Bright
    Stop
  }
}

Actor AfritBall
{
  Radius 6
  Height 8
  Speed 15
  Damage 8
  Projectile
  RenderStyle Add
  Alpha 0.8
  SeeSound "Imp/Attack"
  DeathSound "Imp/ShotX"
  Decal BaronScorch
  States
  {
  Spawn:
    FRTM AB 5 Bright
    Loop
  Death:
    FRTM CDE 6 Bright
    Stop
  }
}

Actor Comet
{
  Radius 6
  Height 8
  Speed 10
  Damage 5
  SpawnID 250
  Scale 0.55
  Projectile
  SeeSound "Afrit/CometFire"
  DeathSound "Afrit/CometHit"
  Decal Scorch
  States
  {
  Spawn:
    COMT AAAABBBBCCCC 1 Bright A_SpawnItemEx("CometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Loop
  Death:
    COMT D 3 Bright A_SpawnItemEx("CometDeathGlow", 0, 0, 0, 0, 0, 0, 0, 128)
    COMT E 3 Bright A_Explode(80, 80, 0)
    TNT1 A 0 A_SpawnItemEx("CometDeath", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor CometTail
{
  Projectile
  +NoClip
  RenderStyle Add
  Alpha 0.4
  States
  {
  Spawn:
    FRTB ABCDEFGHI 1 Bright
    Stop
  }
}

Actor CometDeathGlow : CometTail
{
  Scale 2.0
  Alpha 0.6
  States
  {
  Spawn:
    FRTB ABCDEFGHI 3 Bright
    Stop
  }
}

Actor CometDeath
{
  Projectile
  RenderStyle Add
  +NoClip
  Alpha 0.7
  States
  {
  Spawn:
    COMT FGHI 3 Bright
    Stop
  }
}

Actor OrbitComet : Comet
{
  SeeSound ""
  +NoClip
  Scale 0.28
  Speed 5
  States
  {
  Spawn:
    COMT AABBCC 1 Bright A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    TNT1 A 0 A_CustomMissile("OrbitComet", 0, 0, 75)
    TNT1 A 0 A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor OrbitComet2 : OrbitComet
{
  States
  {
  Spawn:
    COMT AABBCC 1 Bright A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    TNT1 A 0 A_CustomMissile("OrbitComet2", 0, 0, -75)
    TNT1 A 0 A_SpawnItemEx("OrbitCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
    Stop
  }
}

Actor OrbitCometTail : CometTail
{
  Scale 0.5
}

Actor HellFire
{
  +NoBlockMap
  +Painless
  +BloodlessImpact
  +Missile
  +DropOff
  States
  {
  Spawn:
    TNT1 A 1
    Loop
  Death:
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 0, -180)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 16, -175)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, 32, -170)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, -16, -185)
    TNT1 A 0 Bright A_CustomMissile("HellFire1", 0, -32, -190)
    TNT1 A 10 Bright A_PlaySound("Afrit/Hellfire")
    Stop
  }
}

Actor HellFire1
{
  +Ripper
  +NoExplodeFloor
  +Painless
  +BloodlessImpact
  +Missile
  +DropOff
  Speed 2
  States
  {
  Spawn:
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 0, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, 16, 0)
     TNT1 A 10 A_CustomMissile("HellFire2", 0, -16, 0)
     Stop
  }
}

Actor HellFire2
{
  +Ripper
  +NoExplodeFloor
  +BloodlessImpact
  +DropOff
  +Randomize
  Scale 1.5
  Speed 1
  RenderStyle Add
  Alpha 0.67
  Damagetype "HellFire"
  Obituary "%o was scorched by an Afrit"
  States
  {
  Spawn:
    TNT1 A 8
    FRTF A 3 Bright
    FRTF BC 3 Bright A_Explode(3, 64)
    TNT1 A 0 A_Explode(3, 64)
    TNT1 A 0 A_Jump(191, 4)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, 24, 0)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, 0, 0)
    TNT1 A 0 A_CustomMissile("HellFire2", 0, -24, 0)
    FRTF DEFGHIJKLMNO 3 Bright
    Stop
  }
} 

Shilla doesn't work as intended anymore.

Shilla should be fine as of r3795.

[Enjay]

I've just tried it with r3795 and Shilla's tail still seems horizontal (ie not working) to me.

[randi]

Oh, foo. Should be fixed in r3796, then.

[Enjay]

Yup, that seems to be it.

[Enjay]

Just wondering, what is the amplitude of a floatbob? I'm just trying to get a clear understanding of how likely it is that it might cause problems with shooting at an enemy.

As I said a while back, I didn't experience any real perceptible problem when shooting a lost soul that had been given +FLOATBOB but I was wondering, for example, how short an actor would have to be before the sprite moved totally out of the actors hitbox.

[Gez]

Formula is

Code: Select all • Expand view

       return finesine[MulScale22(((FloatBobPhase + level.maptime) << FRACBITS) + ticfrac, FINEANGLES) & FINEMASK] * 8;

So, it means finesine(value) * 8, and since the finesine table returns fixed point numbers between 0 and 1, the amplitude is 8.

[Enjay]

I'm not quite sure from the formula - is that 8 units for the full amplitude (ie from the top of one wave to the trough of the next) or is that 8 up and 8 down giving a total of 16?

Even with that doubt, either way, it's going to have to be a pretty small target and involve some precision shooting before render-only floatbobbing creates noticeable aiming inconsistencies. I suspect that it may never be noticed in any normal, workable mod.

[Blzut3]

Not to mention if the user has auto aim on then any difference would be corrected.

[Enjay]

Indeed. I suspect even "low" or "very low" would be enough most of the time. With the time spent at the extremes of the floatbob (ie where the sprite is furthest away from the centre of its hitbox) being only a small part of the full cycle, I don't really see this causing a major issue. Hell, some people even include sprites with bigger offsets than that anyway.

[Blue Shadow]

The Afrit doesn't even use floatbob, so how is it relevant or broken?

The version of the Afrit in the Ultimate Torment & Torture and the one in the ZDoom Community Map Project (both, the Afrit itself and the boss of tha map, the Oblivion Demon) have the flag in their code.

[Zhs2]

Confirmed from ZDCMP1. Both enemies mentioned are included.

Code: Select all • Expand view

ACTOR OblivionDemon 222
{ 
   Health 6000 
   Speed 12
   Radius 64
   Height 200
   PainChance 12
   Mass 16000
   +BOSS
   Meleedamage 40 
   SeeSound "OblivSight"
   PainSound "baron/pain"
   DeathSound "OblivDeath"
   ActiveSound "baron/active"
   MeleeSound "baron/melee"
   Missiletype "OblivionBall"
   MissileHeight 88
   REACTIONTIME 8
   MONSTER
   Scale 3.0
   +FLOORCLIP
   +NORADIUSDMG
   +NOGRAVITY
   +FLOATBOB
   +FLOAT
   Obituary "%o was nuked into oblivion by the Oblivion Demon" 
   HitObituary "%o found the Oblivion Demon too hot to handle." 
   States 
   { 
   Spawn:
      FRIT ABCD 4 Bright A_Look 
      Loop
   See:
      FRIT A 0 A_CustomMissile("OblivionOrbitComet", 44, 0, 0)
      FRIT A 0 A_CustomMissile("OblivionOrbitComet2", 44, 0, 180)
      FRIT AABBCCDD 2 Bright A_Chase 
      Goto See +2
   Melee:
      FRIT ST 8 Bright A_FaceTarget
      FRIT U 6 Bright A_MeleeAttack
      Goto See +2
   Missile:
      FRIT E 0 A_Jump(196,15)
      FRIT EF 6 BRIGHT A_FaceTarget
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 0)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 30)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 60)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 90)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 120)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 150)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, 180)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, -150)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, -120)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, -90)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, -60)
      FRIT G 6 BRIGHT A_CustomMissile ("OblivionFireSummoner", 88, 0, -30)
      GoTo See +2
      FRIT E 0 A_Jump(160,4)
      FRIT EF 6 Bright A_FaceTarget
      FRIT G 6 Bright A_CustomMissile ("OblivionBall", 88, 0, 0)
      Goto See +2
      FRIT E 0 A_Jump(128,8)
      FRIT EF 6 Bright A_FaceTarget
      FRIT G 0 BRIGHT A_PlaySound("OblivAttack")
      FRIT G 0 Bright A_CustomMissile("OblivionComet", 88, 0, 0)
      FRIT G 0 Bright A_CustomMissile("OblivionComet", 88, 0, 30)
      FRIT G 5 BRIGHT A_CustomMissile("OblivionComet", 88, 0, -30)
      FRIT G 0 Bright A_CustomMissile("OblivionComet", 88, 0, 15)
      FRIT G 5 Bright A_CustomMissile("OblivionComet", 88, 0, -15)
      Goto See +2
      FRIT EF 6 BRIGHT A_FaceTarget
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionBall", 88, 0, 0)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionBall", 88, 0, 10)
      FRIT G 0 BRIGHT A_CustomMissile ("OblivionBall", 88, 0, -10)
      GoTo See +2
   Pain: 
      FRIT HH 4 Bright A_Pain 
      Goto See +2
   Death: 
      FRIT I 0 Bright A_NoGravity
      FRIT I 6 Bright A_Scream
      FRIT J 5 Bright A_NoBlocking
      FRIT KLMNOPQR 4 Bright
      Stop 
   } 
}

actor OblivionComet
{
    Radius 12
    Height 16
    Speed 10
    Damage 20
    ExplosionDamage 160
    ExplosionRadius 320
    Scale 1.1
    PROJECTILE
    SeeSound "OvlivAttack"
    DeathSound "CometExplosion"
    MissileType OblivionCometTail
    MissileHeight 0
    States
    {
    Spawn:
        COML AAAABBBBCCCC 1 Bright A_MissileAttack
        Loop
    Death:
        COML D 3 Bright A_CustomMissile("OblivionCometDeathGlow", 0, 0, 0)
        COML E 3 Bright A_Explode
        COML E 0 A_CustomMissile("OblivionCometDeath", 0, 0, 0)
        Stop
    }
}

actor OblivionCometTail
{
    PROJECTILE
    RENDERSTYLE ADD
    +NOCLIP
    Scale 2.0
    ALPHA 0.4
    States
    {
    Spawn:
        FRTB ABCDEFGHI 1 Bright
        Stop
    }
}

actor OblivionCometDeath
{
    PROJECTILE
    RENDERSTYLE ADD
    +NOCLIP
    Scale 2.0
    ALPHA 0.7
    States
    {
    Spawn:
        COML FGHI 3 Bright
        Stop
    }
}

actor OblivionCometDeathGlow : OblivionCometTail
{
    Scale 4.0
    Alpha 0.6
    States
    {
    Spawn:
        FRTB ABCDEFGHI 3 Bright
        Stop
    }
}

actor OblivionOrbitCometTail : OblivionCometTail
{
    Scale 1.0
}

actor OblivionOrbitComet : OblivionComet
{
     SeeSound ""
     +NOCLIP
     Scale 1.0
     Speed 10
     MissileType OblivionOrbitCometTail
     MissileHeight 0
     States
     {
     Spawn:
         COML AABBCC 1 Bright A_MissileAttack
         COML A 0 A_CustomMissile("OblivionOrbitComet", 0, 0, 75)
         COML A 0 A_MissileAttack
         Stop
     }
}

actor OblivionOrbitComet2 : OblivionOrbitComet
{
     Scale 1.0
     MissileType OblivionOrbitCometTail
     Speed 10
     MissileHeight 0
     States
     {
     Spawn:
         COML AABBCC 1 Bright A_MissileAttack
         COML A 0 A_CustomMissile("OblivionOrbitComet2", 0, 0, -75)
         COML A 0 A_MissileAttack
         Stop
     }
}

actor OblivionBall
{
    Radius 12
    Height 16
    Speed 30
    Damage 10
    DONTHURTSHOOTER
    PROJECTILE
    RENDERSTYLE ADD
    ALPHA 0.8
    Scale 2.0
    SeeSound "OblivAttack"
    DeathSound "imp/shotx"
    States
    {
    Spawn:
        FRTM AB 5 Bright
        Loop
    Death:
        FRTM CDE 6 Bright
        Stop
    }
}

actor OblivionFireSummoner
{
    spawnID 238
    Radius 0
    Height 0
    Speed 20
    Scale 0.25
    PROJECTILE
    - NOGRAVITY
    States
    {
    Spawn:
        COML ABCD 4
        Loop
    Death:
        COML D 3 Bright A_CustomMissile("OblivionCometDeathGlow", 0, 0, 0)
        COML E 3 Bright A_Explode
        COML E 0 A_CustomMissile("BurningDeath", 0, 0, 150)
        COML E 0 A_CustomMissile("BurningDeath", 0, 0, -150)
        COML E 0 A_CustomMissile("BurningDeath", 0, 0, 180)
        Stop
    }
}

ACTOR BurningDeath
{
     +FLOORHUGGER
     PROJECTILE
     Speed 36
     +RIPPER
    SeeSound "OblivAttack"
    DeathSound "CometExplosion"
     Damage 4
     RenderStyle ADD
     Height 60
     Radius 24
     States
     {
     Spawn:
          FIRE ABCD 4 BRIGHT
          FIRE EF 4 BRIGHT
          GoTo Spawn+4
     Death:
          FIRE EFGH 4 BRIGHT
          Stop
     }
}

ACTOR Afrit 3120
{ 
   Health 800 
   Speed 6
   Radius 24
   Height 72
   PainChance 50
   Mass 500
   Meleedamage 10 
   SeeSound "baron/sight"
   PainSound "baron/pain"
   DeathSound "baron/death"
   ActiveSound "baron/active"
   MeleeSound "baron/melee"
   Missiletype "AfritBall"
   MissileHeight 44
   REACTIONTIME 8
   MONSTER
   +NORADIUSDMG
   +FLOORCLIP
   +NOGRAVITY
   +FLOATBOB
   +FLOAT
   Obituary "%o was scorched by an Afrit" 
   HitObituary "%o found the Afrit too hot to handle." 
   States 
   { 
   Spawn:
      FRIT ABCD 4 Bright A_Look 
      Loop
   See:
      FRIT A 0 A_CustomMissile("OrbitComet", 44, 0, 0)
      FRIT A 0 A_CustomMissile("OrbitComet2", 44, 0, 180)
      FRIT AABBCCDD 2 Bright A_Chase 
      Goto See +2
   Melee:
      FRIT ST 8 Bright A_FaceTarget
      FRIT U 6 Bright A_ComboAttack
      Goto See +2
   Missile:
      FRIT E 0 A_Jump(128,4)
      FRIT EF 6 Bright A_FaceTarget
      FRIT G 6 Bright A_ComboAttack
      Goto See +2
      FRIT EF 6 Bright A_FaceTarget
      FRIT G 6 Bright A_CustomMissile("Comet", 44, 0, 0)
      Goto See +2
   Pain: 
      FRIT HH 4 Bright A_Pain 
      Goto See +2
   Death: 
      FRIT I 0 Bright A_NoGravity
      FRIT I 6 Bright A_Scream
      FRIT J 5 Bright A_NoBlocking
      FRIT KLMNOPQR 4 Bright
      Stop 
   } 
}

actor Comet
{
    Radius 6
    Height 8
    Speed 10
    Damage 5
    ExplosionDamage 40
    ExplosionRadius 80
    Scale .55
    PROJECTILE
    SeeSound "CometLaunch"
    DeathSound "CometExplosion"
    MissileType CometTail
    MissileHeight 0
    States
    {
    Spawn:
        COMT AAAABBBBCCCC 1 Bright A_MissileAttack
        Loop
    Death:
        COMT D 3 Bright A_CustomMissile("CometDeathGlow", 0, 0, 0)
        COMT E 3 Bright A_Explode
        COMT E 0 A_CustomMissile("CometDeath", 0, 0, 0)
        Stop
    }
}

//******************************************************************************************

actor CometTail
{
    PROJECTILE
    RENDERSTYLE ADD
    +NOCLIP
    ALPHA 0.4
    States
    {
    Spawn:
        FRTB ABCDEFGHI 1 Bright
        Stop
    }
}

//******************************************************************************************

actor CometDeath
{
    PROJECTILE
    RENDERSTYLE ADD
    +NOCLIP
    ALPHA 0.7
    States
    {
    Spawn:
        COMT FGHI 3 Bright
        Stop
    }
}

//******************************************************************************************

actor CometDeathGlow : CometTail
{
    Scale 2.0
    Alpha 0.6
    States
    {
    Spawn:
        FRTB ABCDEFGHI 3 Bright
        Stop
    }
}

//******************************************************************************************

actor OrbitCometTail : CometTail
{
    Scale .5
}

//******************************************************************************************

actor OrbitComet : Comet
{
     SeeSound ""
     +NOCLIP
     Scale .28
     Speed 5
     MissileType OrbitCometTail
     MissileHeight 0
     States
     {
     Spawn:
         COMT AABBCC 1 Bright A_MissileAttack
         COMT A 0 A_CustomMissile("OrbitComet", 0, 0, 75)
         COMT A 0 A_MissileAttack
         Stop
     }
}

//******************************************************************************************

actor OrbitComet2 : OrbitComet
{
     MissileType OrbitCometTail
     MissileHeight 0
     States
     {
     Spawn:
         COMT AABBCC 1 Bright A_MissileAttack
         COMT A 0 A_CustomMissile("OrbitComet2", 0, 0, -75)
         COMT A 0 A_MissileAttack
         Stop
     }
}

//******************************************************************************************

actor AfritBall
{
    Radius 6
    Height 8
    Speed 15
    Damage 8
    PROJECTILE
    RENDERSTYLE ADD
    ALPHA 0.8
    SeeSound "imp/attack"
    DeathSound "imp/shotx"
    States
    {
    Spawn:
        FRTM AB 5 Bright
        Loop
    Death:
        FRTM CDE 6 Bright
        Stop
    }
}