Immoral Conduct: Decorate Edition [UPDATE: 8-1-2019]

[wildweasel]

Amen to that, back in the hayday i came up with some pretty nifty stuff in edge. oh btw, wildweasel, do you still have that shitty rework of that edge mod i sent to you when i was doomer1? you know, the one with all the bullets shooting slowly and such?

I don't, sorry. I lost a lot of things to a hard drive crash a few years back.

[Crudux Cruo]

oh poo. anyhow, i may take a whack at the shotgun alt attacks since noone else has gotten to it yet; if it was me i would change the grenade slug to a thrown grenade, much like another weapon i cant remember which on it was.

[wildweasel]

oh poo. anyhow, i may take a whack at the shotgun alt attacks since noone else has gotten to it yet; if it was me i would change the grenade slug to a thrown grenade, much like another weapon i cant remember which on it was.

Remember, for now, we're trying to mimic as closely as possible the behavior of the original mod. I do recall the Flak Shotgun having a grenade-launch altfire, but I forget its specifics...

[-Ghost-]

This is probably outside the scope of what you're doing, but will you guys eventually be sprucing up some of the weapon sprites? Most are okay, but some like the assault rifle look pretty bad.

[Kinsie]

This is probably outside the scope of what you're doing, but will you guys eventually be sprucing up some of the weapon sprites? Most are okay, but some like the assault rifle look pretty bad.

Remember, the last release of Immoral Conduct was over a decade ago. Things have changed since then.

I suggest keeping the graphics as is, but minor tweaking to look right on widescreen displays (shotgun reload etc.) wouldn't go amiss. Maybe as a separate WAD, if need be?

[Snarboo]

I do recall the Flak Shotgun having a grenade-launch altfire, but I forget its specifics...

The shotgun secondaries are on my TODO list right after I redo the knife's behavior.

Edit:
The biggest problem with replacing graphics is that they are named very strangely, but it's not impossible. If I had to enhance ICD, I'd rather just start over and make an enhanced mod inspired by ICD.

[-Ghost-]

Yeah, most of the weapons are fine, it's just one or two that stick out pretty badly compared to the rest.

[TheMightyHeracross]

Except he's porting the mod, not remaking it. All he's doing is making a version for ZDoom. I don't think he should touch the sprites.

[Crudux Cruo]

Code: Select all

ACTOR ICD_Remington : BaseWeapon
{
	Game Doom
	Weapon.AmmoUse 1
	Weapon.AmmoGive 0
	Weapon.AmmoType "ICD_RemingtonMagazine"
	Weapon.AmmoType2 "ICD_Shells"
	Inventory.PickupMessage "$GotRemington"
	Tag "$TAG_Remington"
	Weapon.UpSound "weapons/generic/weaponup"
	+WEAPON.AMMO_OPTIONAL
	+WEAPON.NOALERT
	Tag "Remington Shotgun"
	States
	{
		Select:
			TNT1 A 0 A_JumpIfInventory("ICD_RemingtonUpgrade",1,"Upgrade")
			SHTG A 1 A_Raise
			Goto Select+1
		Deselect:
			SHTG A 1 A_Lower
			Loop
		Ready:
			TNT1 A 0 A_JumpIfInventory("ICD_RemingtonUpgrade",1,"Upgrade")
			SHTG A 1 A_WeaponReady(WRF_ALLOWRELOAD)
			Loop
		Fire:
			TNT1 A 0 A_JumpIfInventory("ICD_RemingtonMagazine",1,2)
			TNT1 A 0 A_JumpIfInventory("ICD_Shells", 1, "Reload")
			Goto Ready
			TNT1 A 0 A_AlertMonsters
			TNT1 A 0 A_Gunflash
			TNT1 A 0 A_PlaySound("weapons/remington/fire", CHAN_WEAPON)
			SHTG A 1 A_FireBullets(5,4,9,5,"ICD_ShotgunBulletPuff")
			TNT1 AAAAA 0 A_FireCustomMissile("ICD_Gun3_Sparks", frandom(-5,5),0,5,0,0,frandom(-5,5))
			TNT1 AAAA 0 A_FireCustomMissile("ICD_SSGSmoke1", frandom(-9,9),0,5,0,0,frandom(-5,5))
			SHTG A 2
			SHTG E 2
			SHTG A 3
			SHTG B 2
			SHTG C 2
			SHTG Q 4
			SHTG R 2 A_PlaySound("weapons/remington/cock", 6)
			SHTG R 2 A_FireCustomMissile("ICD_ShotgunShellSpawner1", 0, 0, 5, -4)
			SHTG Q 4
			SHTG C 3
			SHTG B 2
			SHTG A 1
			SHTG A 3 A_Refire
			Goto Ready
		AltFire:
		    SHTG A 0 A_JumpIfInventory("ICD_GrenadeCheck",1,3)
			SHTG A 0 A_TakeInventory("ICD_RocketAmmo",1)
			SHTG A 0 A_GiveInventory("ICD_GrenadeCheck",1)
			SHTG A 1
		   	SHTG F 3 
		   	SHTG G 4 
		   	SHTG H 20 A_PLAYSOUND("weapons/grenade/flare")
		   	SHTG H 2 A_PLAYSOUND("weapons/grenade/hgren2")
		   	SHTG H 2
		   	SHTG H 10 
		   	SHTG H 2 A_GunFlash("AltFlash")
		   	SHTG H 10 A_FireCustomMissile("ICD_ThrownGrenade",2,0,5,-2,0,4)
		   	SHTG G 4 A_TakeInventory("ICD_GrenadeCheck",1)
		   	SHTG F 4
			Goto Ready
		Reload:
			SHTG A 1 A_WeaponReady
			TNT1 A 0 A_JumpIfInventory("ICD_RemingtonMagazine",8,"Ready")
			TNT1 A 0 A_JumpIfInventory("ICD_Shells", 1, 1)
			Goto Ready
			TNT1 A 0 A_PlaySound("weapons/generic/emptyclick2")
			SHTG A 1
			SHTG E 2
			SHTG A 2
			SHTG G 3
			SHTG H 3
			TNT1 A 4
			SHTG I 3
		Reload.Actual:
			SHTG J Random(2,4) // Also not 100% accurate, but it's closer to how it was in EDGE! (Snarboo)
			SHTG M 3
			SHTG K 3
			SHTG L 3
			TNT1 A 0 A_PlaySound("weapons/doublebarrel/load", 6)
			TNT1 A 0 A_TakeInventory("ICD_Shells",1,TIF_NOTAKEINFINITE)
			TNT1 A 0 A_GiveInventory("ICD_RemingtonMagazine",1)
			SHTG N 3 A_WeaponReady(WRF_NOBOB)
			SHTG J random(2,4) A_WeaponReady(WRF_NOBOB)
			TNT1 A 0 A_JumpIfInventory("ICD_RemingtonMagazine", 8, "Reload.Done")
			TNT1 A 0 A_JumpIfInventory("ICD_Shells", 1, "Reload.Actual")
		Reload.Done:
			SHTG I 2
			TNT1 A 2
			SHTG H 3
			SHTG G 3
			SHTG A 3
			SHTG B 2
			SHTG C 3 A_PlaySound("weapons/remington/cock", 6)
			SHTG D 3
			SHTG C 4
			SHTG B 2
			SHTG A 1
			Goto Ready
		Flash:
			SHTF B 1 bright	A_Light(1)
			SHTF A 2 bright A_Light(2)
			TNT1 A 0 A_Light(0)
			Goto LightDone
	   	AltFlash: 
			BFGG D 2 A_PLAYSOUND("weapons/grenade/noway")
			BFGG E 2
			BFGG F 2
			Goto LightDone
		Upgrade:
			TNT1 A 0 A_SelectWeapon("ICD_FlakRemington")
			Goto Deselect
	}
}

ACTOR ICD_RemingtonUpgrade : CustomInventory
{
	Inventory.MaxAmount 1
	Inventory.Icon SHOTA0
	+INVENTORY.IGNORESKILL
	States
	{
		Use:
			TNT1 A 0
			FAIL
	}
}

ACTOR ICD_RemingtonMagazine : Ammo
{
	Inventory.MaxAmount 8
	Ammo.BackpackAmount 0
	Ammo.BackpackMaxAmount 8
	Inventory.Icon SHELA0
	+INVENTORY.IGNORESKILL
}

ACTOR ICD_GrenadeCheck : Ammo
{
	Inventory.MaxAmount 1
	Ammo.BackpackAmount 0
	Ammo.BackpackMaxAmount 1
	+INVENTORY.IGNORESKILL
}

So here's a semi-functional version of the unupgraded shotgun's secondary. it counts grenades as well. problem? how do i use jumpifnoammo if i cant set the secondary ammo as grenades? and jumpifinventory only works on a equal or greater than scale, so there's no jump command to make it jump to a different state (ready) if grenade ammo is out.

Too bad i couldn't do JumpIfInventory("ammo",-1, "Ready") for a "less than" rather than the standard "equal or greater than" code. seems pretty easy to code in too but... oh well.

Anyone got any ideas?

[Snarboo]

Anyone got any ideas?

Try this instead:

Code: Select all

	AltFire:
                SHTG A 0 A_JumpIfInventory("ICD_RocketAmmo",1,1)
                Goto Ready
		SHTG A 0 A_TakeInventory("ICD_RocketAmmo",1)
		SHTG A 1
		SHTG F 3 
		SHTG G 4 
		SHTG H 20 A_PLAYSOUND("weapons/grenade/flare")
		SHTG H 2 A_PLAYSOUND("weapons/grenade/hgren2")
		SHTG H 2
		SHTG H 10 
		SHTG H 2 A_GunFlash("AltFlash")
		SHTG H 10 A_FireCustomMissile("ICD_ThrownGrenade",2,0,5,-2,0,4)
		SHTG G 4
		SHTG F 4
	        Goto Ready

Edit:
Just tested to see if this would work, and it does! :)

[Crudux Cruo]

Cool, that's one down. IDK if ill do the other one today with turkey day and all but ill see what i can whip up

Also, some more bugs:

Rifle Ammo Pickup uses pistol clip sprite
Assault Rifle Pickup only gives 35 Ammo, and you have to reload after picking up.
Nazi's dont drop UZI's (always thought that was funny since UZI's are an israeli invention)

[wildweasel]

Rifle Ammo Pickup uses pistol clip sprite

Seems to be intentional; DDFTHING shows the Rifle clips as using CLIP frame A as their pickup sprite, same as the .45 ammo.

Assault Rifle Pickup only gives 35 Ammo, and you have to reload after picking up.

I've fixed the AR pickup, and I'll look into making sure all picked up weapons start loaded. I may or may not have completely screwed the ammo balance with this change.

Nazi's dont drop UZI's (always thought that was funny since UZI's are an israeli invention)

[/quote][/quote]
Something I'll have to look into soon, as I'll need to implement the actual SS from the mod (I'm pretty sure they have the Uzi attack, smoke effects, and reloading like the other monsters, too).

[Snarboo]

I noticed your recent change, weasel! The behavior of the weapon pickups varies between EDGE versions. In 1.35, you get a full magazine upon picking up any weapon, even a dropped one, but in 1.27, weapons that are dropped give you half ammo, so you usually get half a clip. Not sure how to handle this yet, but the pickups need work.

[HavoX]

Nazi's dont drop UZI's (always thought that was funny since UZI's are an israeli invention)

How is that even a bug? Uzis weren't even around during WW2.

[wildweasel]

Nazi's dont drop UZI's (always thought that was funny since UZI's are an israeli invention)

How is that even a bug? Uzis weren't even around during WW2.

Because Nazis did carry, use, and drop Uzis in ICD-SE.wad, and our current goal is to make it work as closely as possible to the original. We can second-guess Cory Whittle's intentions later.