[.96] Not a bug : Both scripts should work equally

[Costja]

Both of this scripts should work equally (because they don't contain async statements), but the first script gives you 15 health points and the second script gives you 5 health point.

---

Code: Select all

#include "zcommon.acs"

int i = 0;

script 255 (void)
{
   If(i == 0) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got a snack!");
      i++;
   }
   If(i == 1) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got another snack!");
      i++;
   }
   If(i == 2) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got another snack!");
      i++;
   }
   If(i >= 3) {
      Print(s: "They ran out!");
   }
} 

---

Code: Select all

#include "zcommon.acs"

int i = 0;
 
script 254 (void)
{
    acs_execute(255,0);
    acs_execute(256,0);
    acs_execute(257,0);
    acs_execute(258,0);
}

script 255 (void)
{
   If(i == 0) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got a snack!");
      i++;
   }
}

script 256 (void)
{
   If(i == 1) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got another snack!");
      i++;
   }
}
 
script 257 (void)
{
  If(i == 2) {
     GiveInventory("HealthBonus", 5);
     Print(s: "You got another snack!");
     i++;
   }
}

script 258 (void)
{
   If(i >= 3) {
      Print(s: "They ran out!");
   }
} 

[Graf Zahl]

The first script does exactly what is to be expected. The second, however, suffers from synchronization issues. ACS_Execute doesn't run the executed script itself. It just queues the script for execution in thew next tic. But AFAIK the last one queued is the first one executed so they are run in order 258, 257, 256, 255.

In the end both suffer from a simple programming error: What you want is probably:

Code: Select all

script 255 (void)
{
   If(i == 0) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got a snack!");
      i++;
   }
   else If(i == 1) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got another snack!");
      i++;
   }
   else If(i == 2) {
      GiveInventory("HealthBonus", 5);
      Print(s: "You got another snack!");
      i++;
   }
   else If(i >= 3) {
      Print(s: "They ran out!");
   }
}

Without the 'else's all if branches are executed.

[Costja]

Thanks for explanation of ACS_Execute special.

These scripts aren't my (they are from this thread). I simply didn't understand why second script "works".

[Graf Zahl]

Because the queued scripts are executed in reverse order, as I said.

if (i>=3)... first, then
if (i==2), then
if (i==1), then
if (i==0)

And logically then these side effects won't show.

[Bio Hazard]

why not just

Code: Select all

#include "zcommon.acs"

int i=0;
script 255 (void){
	if(i<3){
		GiveInventory("HealthBonus",5);
		if(i==0){Print(s:"You got a snack!");}
		else{Print(s:"You got another snack!");}
		i++;
	}else{Print(s:"They ran out!");}
}

?

[Graf Zahl]

That works as well.