Recreating the ENDGAME script of DOOM2 in a ZDOOM map?

[Tormentor667]

Well, I need to know how I can recreate the ENDGAME script (the one in front of the BOSSBACK, where all your enemies are once more displayed and you kill them by hitting a key) of DOOM2 in a ZDOOM map, that is capable of even displaying and killing DECORATE monsters?

Well, I have a certain idea how this could (?) work but I am not sure so I need professional help. I think it'd be not that hard to spawn monsters in a 3D environment (a map), displaying them with a CAMERA thing and killing them with a ACS script, if "USE" is being hit.

The problem itself is the spawning script for the monsters. Is someone capable of writing me something like that? I think it should be possible to write that with some sort of STRINGS, that you give all of the monsters a number (1,2,3,4,etc) and spawn them via "spawnspot" so you are able to even spawn DECORATE objects quite easily. Each of the monsters has at first a TID of 1 when spawned, if they die, they get a TID of 2, spawn a new TID 1-monster and after the next TID 1 monster is killed, the same thing happens and all the TID 2 things were removed (dead bodies) and so on in a loop.

As far as I know, Cyb did something like that in MM2...

[AgentSpork]

That's the easiest way I could think of to do it. As far as having it trigger when the player presses a key, I don't know. I'm no scripting expert

EDIT: Actually, I've figured out a way.. removed the old code.

Code: Select all

int monsterSpawnList[16] = {    //Monster SpawnID for Thing_SpawnFacing Command
	T_ZOMBIE,
	T_SHOTGUY,
	T_CHAINGUY,
	T_IMP,
	T_DEMON,
	T_SPECTRE,
	T_LOSTSOUL,
	T_CACODEMON,
	T_HELLKNIGHT,
	T_BARON,
	T_REVENANT,
	T_VILE,
	T_ARACHNOTRON,
	T_MANCUBUS,
	T_SPIDERMASTERMIND,
	T_CYBERDEMON };

str monsterNameList[16] = {    //Monster names for Print/HudMessage Command
	"Zombieman",
	"Shotgun Guy",
	"Heavy Weapons Dude",
	"Imp",
	"Demon",
	"Spectre",
	"Lost Soul",
	"Cacodemon",
	"Hell Knight",
	"Baron of Hell",
	"Revenant",
	"Arch Vile",
	"Arachnotron",
	"Mancubus",
	"Spider Mastermind",
	"Cyberdemon" };

Script 50 (void) //Monster Credit Thingy
{
	For(int x = 1; x <= 16; x += 1) //Goes through list of monsters starting at the Zombieman
	{
		Print(s: monsterNameList[x - 1] );    //Prints the monster's name (Hudmessage would work fine as well)
		Thing_SpawnFacing(50,monsterSpawnList[x - 1], 0,51);    //Spawns the monster
		Delay(35 * 5);
		Thing_Destroy(51,0);    //Kills the currently active monster
		Delay(35);
	}    //Loops, moving on to the next monster until it reaches the end of the list
}

Script 51 (void) //Kills monster when player presses use (or whatever)
{
	ACS_Suspend(50,0); //Suspend the monster credit script
	Thing_Destroy(51,0); //Kill currently alive monster
	Delay(35);
}

Simply have your camera set up, and put the player in a small box where all the linedefs are set to trigger Script 51 when the player presses use, and voila! I've tested it and it seems to work just fine.

[Tormentor667]

Thx alot for that script This works pretty well, there is just a single problem I have with the scrpt: First, the "press use" key to kill a monster doesn't work and second all the dead bodies stay... and some of them hide smaller monsters then when it gets to much on the floor. Is there any way how to remove them?

[Tormentor667]

Third problem is, that they don't create a ACTIVE or SEE sound, when they get spawned A good solution would be to spawn the player in front of them so they can see him, the problem behind this, is that they are capable of moving. Is there a way how I can stop them?

[Enjay]

Monster blocking lines? Deactivate them?

I'd also think dropped items would start to pile up too. Making Decorate versions of the monsters specifically for the endgame seems like a good plan. (Graf suggested it over at DRD.) You could even make a single monster that cycles through the whole thing if you didn't need the player to instigate the deaths.

[Tormentor667]

Deactivating them would make them stay still, and that's not what I plan! The problem with the monsterblocking line is that the monster doesn't get spawned if a monster blocking line is in its way!

And the DECORATE thing is a bit complicated and too hard to do for myself and beyond not flexible enough concerning new DECORATE monsters.

[Enjay]

The DECORATE thing would be quite long and a bit tedious to set up, but not overly complex. I'd also think it would be better for new DECORATE monsters because you could dictate exactly what you want them to do rather than relying on the jumps and other random features of the original (unless you wanted that of course). A single decorate item using sprites from all the monsters you want to show would be pretty straight forward (if long-winded).

[pseudo code]

Spawn:
monter1 walk sprite 1 play see sound
monter1 walk sprite 23412341234
monter1 attack sprite 123 (with attack sound/pointer as required)
monter1 walk sprite 1234
monster1 death sprite 123456 (with death sound)
monster2 walk sprite 1 play see sound
monter2 walk sprite 23412341234
monter2 attack sprite 123 (with attack sound/pointer as required)
etc
etc
etc
loop

[/pseudocode]

[Tormentor667]

That's a lot of work and beyond very "hardcoded" and unflexible in the end, isn't it?

[AgentSpork]

Well, it seems quite simple to me. Sure, it'll add a bit of extra stuff to your DECORATE lump, but if that's what you're wanting to do, then it should be more than worth it. Hell, probably more than half of the stuff in the DECORATE lump in my megawad is solely for stuff you only see in the two secret levels. Otherwise there'd only be two enemy definitions and two boss definitions. Currently there's about 6-7 enemy definitions and there will be 4 boss definitions in the end.

My way of doing it would probably be a bit different than Enjay's however. I'd have separate definitions for each monster, like so:

Code: Select all

ACTOR EndZombie			//End Credits Zombieman
{
   SpawnID 211			//SpawnID, for Thing_SpawnFacing
   Speed 0
   SeeSound "grunt/sight"
   AttackSound "grunt/attack"
   DeathSound "grunt/death"
   States
   {
   Spawn:
       POSS A 0
       Goto See
   See:
       POSS AABBCCDDAABBCCDD 5	//Looping See state.. walks around for a bit and then "shoots"
       POSS E 5
       POSS F 5 A_PlaySound("grunt/attack")
       Loop			//Loop!
   Death:
       POSS H 5			//Death state for enemy when the script kills it
       POSS I 5 A_Scream
       POSS J 5 A_Fall
       POSS K 5
       POSS L -1
       Stop
   }
}

I really can't think of any better way to perfectly emulate the Doom 2 ending without adding a lot of bulk onto the DECORATE lump. But as I said, if it's something you're willing to do, then it should not be too big of an issue.

[Tormentor667]

Well, I don't care about the size of the DECORATE lump at all, because it's already huge. The question is, if you are willing to do it ... or explain to me how to do it (DECORATE n00b) for all the DECORATE monsters, that should be drawn in the end?!

You can actually inherit most of the stuff from the original monsters, can't you? All the sounds and stuff, that makes it easier later?!
...for sure this seems to be the best idea but obviously also the most "hardcoded" and time consuming of all, and I am not sure if the effort is worth for just my "Ultimare TNT Endscreen"... I'd be more happy, if this is useful for any later mod with different monsters, that might be interested in using this. Though I'd still be happy to have it in UTNT

[AgentSpork]

Well I've thrown together a little example wad in a few minutes that gives a basic example as to how things could possibly be done. It's nothing special, but it works. It loops through 4 different monsters (because that's about all I got up to before I got bored )

Here's the example WAD.

Here's the script:

---

Code: Select all

#include "zcommon.acs"

Script 1 OPEN
{
	SetMusic("D_READ_M");
	SetPlayerProperty(1,1,PROP_FROZEN);
	ChangeCamera(2,1,0);
	Delay(15);
	ACS_Execute(50,0);
}

//Monster definitions for ending script
//Uses SpawnIDs defined in the DECORATE lump
//NOTE: This is not necessary, it is only here for convenience
//      so that it uses plausable names instead of numbers

#define T_ENDZOMBIE				201
#define T_ENDSHOTGUY			202
#define T_ENDCHAINGUY			203
#define T_ENDIMP				204
#define T_ENDDEMON				205
#define T_ENDSPECTRE			206
#define T_ENDLOSTSOUL			207
#define T_ENDCACODEMON			208
#define T_ENDHELLKNIGHT			209
#define T_ENDBARON				210
#define T_ENDREVENANT			211
#define T_ENDVILE				212
#define T_ENDARACHNOTRON		213
#define T_ENDMANCUBUS			214
#define T_ENDSPIDERMASTERMIND	215
#define T_ENDCYBERDEMON			216

//Monster types for Thing_SpawnFacing
int monsterSpawnList[4] = {
	T_ENDZOMBIE,
	T_ENDSHOTGUY,
	T_ENDCHAINGUY,
	T_ENDIMP};

//Monster names for HudMessage or Print
str monsterNameList[4] = {
	"Zombieman",
	"Shotgun Guy",
	"Heavy Weapons Dude",
	"Imp",};

Script 50 (void) //Monster Credit Thingy
{
	For(int x = 1; x <= 4; x += 1)
	{
		Print(s: monsterNameList[x - 1] );
		Thing_SpawnFacing(1,monsterSpawnList[x - 1], 0,51);
		Delay(35 * 10);
		Thing_Destroy(51,0);
		Delay(35);
	}
	Restart;
}

Script 51 (void) //Kills monster when player presses use (or whatever)
{
	ACS_Suspend(50,0); //Suspend the monster credit script
	Thing_Destroy(51,0); //Kill currently alive monster
	Delay(35);
	ACS_Execute(50,0); //Continue script
}

And here's the DECORATE:

---

Code: Select all

ACTOR EndZombie
{ 
   SpawnID 201          //SpawnID, for Thing_SpawnFacing 
   Speed 0 
   DeathSound "grunt/death"
   MONSTER
   States 
   {
   Spawn:
       POSS A 0
       Goto See
   See:
       POSS A 0 A_PlaySound("grunt/sight")
       POSS ABCDABCDABCD 5
       POSS E 6 
       POSS F 6 A_PlaySound("grunt/attack")
       POSS ABCDABCDABCD 5
       POSS E 6 
       POSS F 6 A_PlaySound("grunt/attack")
       POSS ABCDABCDABCD 5
       POSS E 6 
       POSS F 6 A_PlaySound("grunt/attack")
       POSS ABCDABCDABCD 5
       POSS E 6 
       POSS F 6 A_PlaySound("grunt/attack")
       POSS ABCDABCDABCD 5
       Goto Death
   Death: 
       POSS H 5         //Death state for enemy when the script kills it 
       POSS I 5 A_Scream 
       POSS J 5 A_Fall 
       POSS K 5 
       POSS L 8
       Stop 
   } 
}
 
ACTOR EndShotguy
{ 
   SpawnID 202          //SpawnID, for Thing_SpawnFacing 
   Speed 0 
   DeathSound "grunt/death"
   MONSTER
   States 
   {
   Spawn:
       SPOS A 0
       Goto See
   See:
       SPOS A 0 A_PlaySound("shotguy/sight")
       SPOS ABCDABCDABCD 5
       SPOS E 6 
       SPOS F 6 A_PlaySound("shotguy/attack")
       SPOS ABCDABCDABCD 5
       SPOS E 6 
       SPOS F 6 A_PlaySound("shotguy/attack")
       SPOS ABCDABCDABCD 5
       SPOS E 6 
       SPOS F 6 A_PlaySound("shotguy/attack")
       SPOS ABCDABCDABCD 5
       SPOS E 6 
       SPOS F 6 A_PlaySound("shotguy/attack")
       SPOS ABCDABCDABCD 5
       Goto Death
   Death: 
       SPOS H 5         //Death state for enemy when the script kills it 
       SPOS I 5 A_Scream 
       SPOS J 5 A_Fall 
       SPOS K 5 
       SPOS L 8
       Stop 
   } 
} 

ACTOR EndChainguy
{ 
   SpawnID 203          //SpawnID, for Thing_SpawnFacing 
   Speed 0 
   DeathSound "grunt/death"
   MONSTER
   States 
   {
   Spawn:
       CPOS A 0
       Goto See
   See:
       CPOS A 0 A_PlaySound("shotguy/sight")
       CPOS ABCDABCDABCD 5
       CPOS E 6 
       CPOS FEFEFE 4 A_PlaySound("shotguy/attack")
       CPOS ABCDABCDABCD 5
       CPOS E 6 
       CPOS FEFEFE 4 A_PlaySound("shotguy/attack")
       CPOS ABCDABCDABCD 5
       CPOS E 6 
       CPOS FEFEFE 4 A_PlaySound("shotguy/attack")
       CPOS ABCDABCDABCD 5
       CPOS E 6 
       CPOS FEFEFE 4 A_PlaySound("shotguy/attack")
       CPOS ABCDABCDABCD 5
       Goto Death
   Death: 
       CPOS H 5         //Death state for enemy when the script kills it 
       CPOS I 5 A_Scream 
       CPOS J 5 A_Fall 
       CPOS KLM 5
       CPOS N 8
       Stop 
   } 
} 

ACTOR EndImp
{ 
   SpawnID 204          //SpawnID, for Thing_SpawnFacing 
   Speed 0 
   DeathSound "grunt/death"
   MONSTER
   States 
   {
   Spawn:
       TROO A 0
       Goto See
   See:
       TROO A 0 A_PlaySound("imp/sight")
       TROO ABCDABCDABCD 5
       TROO EF 5 
       TROO G 6 A_PlaySound("imp/attack")
       TROO ABCDABCDABCD 5
       TROO EF 5 
       TROO G 6 A_PlaySound("imp/attack")
       TROO ABCDABCDABCD 5
       TROO EF 5 
       TROO G 6 A_PlaySound("imp/attack")
       TROO ABCDABCDABCD 5
       TROO EF 5 
       TROO G 6 A_PlaySound("imp/attack")
       TROO ABCDABCDABCD 5
       Goto Death
   Death: 
       TROO H 5         //Death state for enemy when the script kills it 
       TROO I 5 A_Scream 
       TROO J 5 A_Fall 
       TROO KL 5 
       TROO M 8
       Stop 
   } 
}

Both of which can of course be found in the WAD as well.

[Tormentor667]

Okay, this seems to be logic and working... the only problem with this is, that you need a lot of knowledge concerning the sprites and frames of the monsters from the MRP and DOOM2 to create all of these T_ENDxxx monsters... this will take a huge amount of time, thats quite certain.

[Phobus]

The knowledge on Doom2 monsters is now available in the wiki, or so I'm led to believe. Perhaps that will help out?

[AFADoomer]

See attached for complete Doom II finale...

It's not 100% perfect, but pretty close. Just load a new game (MAP01).

Credit to AgentSpork for original script.

[AgentSpork]

Yeah, I'm sure with a couple more tweaks (frame timing, some sound propblems), it could be almost exactly the same as the original.